Expression x, t;
int depth = 5;
PFont font;

void setup(){
  size(500,200);
  font = loadFont("silkscreen.vlw");
  textFont( font );
  x = recursiveExpression( randomExpression(null), depth );
  redraw();
  noLoop();
}
//-------------------
void draw(){
  background(255);
  stroke(0);
  noFill();
  rect( 0,0,width-1, height-1 );
  x.draw(width/2 - x.width()/2,height/2 - x.height()/2);
}
//-------------------
void keyPressed(){
  if(key>='1' && key<='9') depth = key - '1';
  x = recursiveExpression( randomExpression(null), depth );
  redraw();
}
//-------------------
void mousePressed(){
  x = recursiveExpression( randomExpression(null), depth );
  redraw();
}
//-------------------
Expression recursiveExpression(Expression ex, int level){
  for(int i=0;i<ex.subExp.length;i++){
    // randomExpression(ex) parameter is parent
    if(level==0)
      ex.subExp[i] = new NumericalValue( ex );
    else
      ex.subExp[i] = recursiveExpression( randomExpression(ex) , level-1 );
  }
  return ex;
}
//-------------------
Expression randomExpression(Expression parent){
  int x = (int) (9*random(1.0));
  int y = (int) (3*random(1.0));
  Expression ex = null;
  if(x==0) ex = new Addition( parent );
  if(x==1) ex = new Multiplication( parent );
  if(x==2) ex = new Sqrt( parent );
  if(x==3) ex = new Parentheses( parent );
  if(x==4) ex = new Division( parent );
  if(x==5) ex = new Power( parent );
  if(x==6){
    if(y==0) ex = new Cos( parent );
    if(y==1) ex = new Sin( parent );
    if(y==2) ex = new Tan( parent );
  }
  if(x==7) ex = new Log( parent );
  if(x==8) ex = new Abs( parent );
  return ex;
}
//-------------------
class Expression{
  Expression[] subExp;
  Expression parent;
  int w, h;
  int width(){
    if(subExp!=null) if(subExp.length>0) return w + subExp[0].width();
    return w;
  }
  int height(){
    if(subExp!=null) if(subExp.length>0) return h + subExp[0].height();
    return h;
  }
  void draw(int x, int y){}
  void setSubExpression(int index, Expression e){
    subExp[index] = e;
    e.parent = this;
  }
  void initSubExp(int len){
    subExp = new Expression[len];
      for(int i=0;i<len;i++)
        subExp[i] = new NumericalValue(this);
  }
}
//-------------------