//---------------------------------------------
class Beam {

  float originX, originY, vecX, vecY;
  int age, res, range, originalAge;
  float[] beamX, beamY, beamVX, beamVY;
  boolean ignore;
  Beam nextBeam; //next object in a linked list

  //---------------------------------------------
  Beam(float x, float y, float vx, float vy){
    ignore = false;
    age = 20;
    originalAge = 20;
    range = 400;
    res = 150;
    originX = x;
    originY = y;
    vecX = vx/dist(0,0,vx,vy);
    vecY = vy/dist(0,0,vx,vy);
    beamX = new float[res];
    beamY = new float[res];
    beamVX = new float[res];
    beamVY = new float[res];
    for(int i=0;i<res;i++){
      float randPos = random(0,range);
      beamX[i] = originX + (randPos+10) * vecX;
      beamY[i] = originY + (randPos+10) * vecY;
      beamVX[i] = vecY * sin(randPos/10.0) * random(0.0,1.2);
      beamVY[i] = -vecX * sin(randPos/10.0) * random(0.0,1.2);
    }
  }

  //---------------------------------------------
  void addBeam(float x, float y, float vx, float vy){
    if(nextBeam!=null){
      nextBeam.addBeam( x, y, vx, vy);
    } 
    else {
      nextBeam = new Beam(x, y, vx, vy);
    }
  }

  //---------------------------------------------
  void update(){
    //Updates the shot's position
    if(!ignore && age==0) ignore = true;
    if(!ignore){

      if(age==originalAge) checkForKill();

      age--;

      for(int i=0;i<res;i++){
        beamX[i] += beamVX[i];
        beamY[i] += beamVY[i];
      }
      visualize();

    }
    //Updates the rest of the shots in the linked list
    if(nextBeam!=null){
      nextBeam.update();
      // Removes redundant objects
      if(nextBeam.ignore) nextBeam = nextBeam.nextBeam;
    }
  }

  //---------------------------------------------
  void checkForKill(){

    float vx, vy, alfa, beta, t, dotProd;
    vx = vecX;
    vy = -vecY;
    alfa = vx/(vx*vx + vy*vy);
    beta = vy/(vx*vx + vy*vy);
    t = abs( alfa*(originY-enemy.y) + beta*(originX-enemy.x) );
    // if the dotProd > 0 then the beam points away from the enemy
    dotProd = vecX*(originX-enemy.x) + vecY*(originY-enemy.y);

    if( t < 12 && dotProd < 0) enemy.kill();
  }

  //---------------------------------------------
  void visualize(){
    //Draws the shot
    for(int i=0;i<res;i++){
      stroke(age*10/originalAge,age*255/originalAge,age*10/originalAge);
      point(beamX[i],beamY[i]);
    }
  }
}