//---------------------------------------------
class Blast {

  int density, r, g, b;
  float[] posX, posY, velX, velY;
  float originalAge, age;
  boolean ignore;
  Blast nextBlast; //next object in a linked list

//---------------------------------------------
  Blast(float x, float y){
    ignore = false;
    r = 0;
    g = 255;
    b = 0;
    age = 20;
    originalAge = 20;
    density = 30;
    posX = new float[density];
    posY = new float[density];
    velX = new float[density];
    velY = new float[density];
    for(int i=0; i<density; i++) {
      posX[i] = x;
      posY[i] = y;
      float angle = random(-PI,PI);
      velX[i] = 3*cos(angle);
      velY[i] = 3*sin(angle);
    }
  }
  
//---------------------------------------------
  Blast(float x, float y, float fluff, int inDensity, int inAge, int ir, int ig , int ib){
    ignore = false;
    r = ir;
    g = ig;
    b = ib;
    age = inAge;
    originalAge = inAge;
    density = inDensity;
    posX = new float[density];
    posY = new float[density];
    velX = new float[density];
    velY = new float[density];
    for(int i=0; i<density; i++) {
      posX[i] = x;
      posY[i] = y;
      float angle = random(-PI,PI);
      velX[i] = random(4-fluff,4)*cos(angle);
      velY[i] = random(4-fluff,4)*sin(angle);
    }
  }

//---------------------------------------------
  void addBlast(float x, float y, float influff, int indensity, int inage, int r, int g, int b){
    if(nextBlast!=null){
      nextBlast.addBlast( x, y, influff, indensity, inage, r, g, b);
    } else {
      nextBlast = new Blast(x, y, influff, indensity, inage, r, g, b);
    }
  }

//---------------------------------------------
  void addBlast(float x, float y){
    if(nextBlast!=null){
      nextBlast.addBlast( x, y);
    } else {
      nextBlast = new Blast(x, y);
    }
  }

//---------------------------------------------
  void update(){
    if(age!=0){
      age--;
      for(int i=0; i<density; i++) {
        posX[i] += velX[i];
        posY[i] += velY[i];
        velX[i] = velX[i]*0.95;
        velY[i] = velY[i]*0.95;
      }
      visualize();
    } else {
      ignore = true;
    }
    //Updates the rest of the blasts in the linked list
    if(nextBlast!=null){
      nextBlast.update();
      // Removes redundant objects
      if(nextBlast.ignore) nextBlast = nextBlast.nextBlast;
    }
  }

//---------------------------------------------
  void visualize(){
    //Draws the ship
    for(int i=0; i<density; i++) {
      stroke(age*r/originalAge,age*g/originalAge,age*b/originalAge);
      point(posX[i],posY[i]);
    }
  }

}