PImage[] frames;
float[][] mask;
float decay = 0.0016;
//--------------------
void setup(){
  size(224,224);
  frames = new PImage[4];
  frames[0] = loadImage("winter.PNG");
  frames[1] = loadImage("spring.PNG");
  frames[2] = loadImage("summer.PNG");
  frames[3] = loadImage("autumn.PNG");
  mask = new float[width][height];
}
//--------------------
void draw(){
  loadPixels();
  for(int i=0 ; i<width ; i++)
    for(int j=0 ; j<width ; j++){
      float brush = (mousePressed ? brushPower(mouseX,mouseY,i,j) : 0 );
      mask[i][j] = constrain( mask[i][j] - decay + brush, 0 , 1 );
      pixels[i+j*width] = getPixel(i,j);
    }
  updatePixels();
}
//--------------------
float brushPower(int ox, int oy,int x, int y){
  float d = dist(ox,oy,x,y);
  return 0.03*exp(-d*d*0.0005);
}
//--------------------
color getPixel(int i, int j){
  float amount = mask[i][j];
  int index = i+j*width;
  if(amount<0.3333)
    return lerpColor(frames[0].pixels[index],frames[1].pixels[index],3*amount);
  else if(amount<0.6666)
    return lerpColor(frames[1].pixels[index],frames[2].pixels[index],3*amount-1);
  else
    return lerpColor(frames[2].pixels[index],frames[3].pixels[index],3*amount-2);
}