class Sperm extends Entity{
  int id = 0;
  float turnSpeed = 0.15;
  float acceleration = 0.2;
  float defaultSpeed = 1;
  float tailTimer;
  float eatDistance = 7;
  float pushDistance = 40;
  int pulseCost = 30;
  int charge = 0;
  int score = 0;
  int scoreX = 0;
  int scoreY = 0;
  //-------------
  Sperm(int ix, int iy, int id){
    super(ix,iy);
    this.id = id;
    if(id==0) setScorePos(8,25);
    if(id==1) setScorePos(width-10,25);
    tailTimer = 0;
    isPushable = true;
  }
  //-------------
  void update(){
    charge++;
    tailTimer += mag(vx,vy)*defaultSpeed;
    if( mag(vx,vy) > defaultSpeed ){
      float slowX = vx*friction;
      float slowY = vy*friction;
      vx -= slowX*gameSpeed;
      vy -= slowY*gameSpeed;
    }
    super.update();
    
    for( int i=0 ; i<entities.size() ; i++ ){
      Entity e = (Entity) entities.elementAt(i);
      if(e.isEatable){
        float d = dist(e.x,e.y,x,y);
        if( d < eatDistance ){
          e.kill();
          score++;
        }
      }
    }
  }
  //-------------
  void visualize(){
    pushMatrix();
    translate(x,y);
    rotate( atan2(vy,vx) );

    for(int i=0; i<20; i++){
      stroke(32,(20-i)*255/20);
      point( -i , 0.1*(i+2)*sin( i*0.5-tailTimer*0.2 ) );
    }

    fill(255);
    stroke(32);
    ellipse(0,0,5,5);

    popMatrix();
    
    fill(255,64+32*cos(0.01*tailTimer) );
    if(id==0)
      textAlign(LEFT);
    else
      textAlign(RIGHT);
    text(score,scoreX,scoreY);
  }
  //-------------
  void setScorePos(int x, int y){
    scoreX = x;
    scoreY = y;
  }
  //-------------
  void boost(){
    float v = mag(vx,vy);
    vx += acceleration*gameSpeed*vx / v;
    vy += acceleration*gameSpeed*vy / v;
  }
  //-------------
  void turn(float dir){
    float r = turnSpeed*gameSpeed*dir;
    float newVx = vx*cos(r) + vy*sin(r);
    float newVy = vy*cos(r) - vx*sin(r);
    vx = newVx;
    vy = newVy;
  }
  //-------------
  void pulse(){
    if( charge < pulseCost )
      return;
    else
      charge = 0;
    
    entities.add( new Pulse( x+vx,y+vy,pushDistance ) );
    for( int i=0 ; i<entities.size() ; i++ ){
      Entity e = (Entity) entities.elementAt(i);
      if(e.isPushable){
        float d = dist(e.x,e.y,x,y);
        if( d < pushDistance && d>1 ){
          e.vx += 50*(e.x-x)/sq(d);
          e.vy += 50*(e.y-y)/sq(d);
        }
      }
    }
  }
}