float rot = 0f;
float step = 2f;
Spore[] spores;
BlackSun sun;
PImage sporeTexture;

//------------------------------------------------
void setup() {

  size(200,200,P3D);

  reConstruct();

}
//------------------------------------------------
void reConstruct() {
  int w = 32;
  int half = w/2;
  sporeTexture = createImage(w,w,ARGB);
  for(int i=0 ; i<w ; i++ ){
    for(int j=0 ; j<w ; j++ ){
      float d = 255 * sq( sq( 1 - dist(i,j,half,half) / half ) );
      float alph = constrain( d, 0, 255 );
      sporeTexture.pixels[i+j*w] = color(255, alph );
    }
  }
      
  sun = new BlackSun(45);
  spores = new Spore[300];
  for(int i=0 ; i<spores.length ; i++ )
    spores[i] = new Spore( random(0.25,1), random(40,45), 0.5 );

}
//------------------------------------------------
void draw() {  

  background( 0 );

  translate( width/2, height/2, height/2 );
  scale(0.7*width/200);
  rot+=0.005;

  sun.draw();

  sphereDetail(3);
  for(int i=0 ; i<spores.length ; i++ ){
    spores[i].update(); 
    spores[i].draw(); 
  }

  //filter(INVERT);
}
//------------------------------------------------
void mouseReleased(){
  if(mouseX<30 && mouseY<30) reConstruct();

}
//------------------------------------------------
class Spore{
  float x,y,z,vx,vy,vz,radius,distance,size;
  //----------
  Spore(float radius, float distance, float speed){
    this.radius = radius;
    this.distance = distance;
    this.size = 1+sq( sq( random(0,1.1) ));
    this.size *= 8.0 / sporeTexture.width;
    x = random(-1,1) + random(-1,1) + random(-1,1);
    y = random(-1,1) + random(-1,1) + random(-1,1);
    z = random(-1,1) + random(-1,1) + random(-1,1);
    float d = mag(x,y,z);
    x *= distance/d;
    y *= distance/d;
    z *= distance/d;
    vx = speed * random(-1,1);
    vy = speed * random(-1,1);
    vz = speed * random(-1,1);
    float factor = (vx*x + vy*y + vz*z) / sq( mag(x,y,z) );
    vx -= factor*x;
    vy -= factor*y;
    vz -= factor*z;
  }
  //----------
  void draw(){
    noStroke();
    fill(255,128,0,128);
    translate( x, y, abs(z) ); // no need to draw invisible spores
    scale( this.size );
    image(sporeTexture,-sporeTexture.width/2,-sporeTexture.height/2);
    scale( 1f/this.size );
    translate( -x, -y, -abs(z) );
    stroke(255,32);
    for(int i=0 ; i<spores.length ; i++ ){
      if( dist(x,y,abs(z),spores[i].x,spores[i].y,abs(spores[i].z)) < 10 )
        line(x,y,abs(z),spores[i].x,spores[i].y,abs(spores[i].z));
    }
  }
  //----------
  void update(){
    x += vx;
    y += vy;
    z += vz;
    /*
    float d = mag(x,y,z);
     x *= distance/d;
     y *= distance/d;
     z *= distance/d;*/
    float f = sq( mag(vx,vy,vz) / distance );
    vx -= x*f;
    vy -= y*f;
    vz -= z*f;
  }
}
//------------------------------------------------
class BlackSun{
  float radius;
  //----------
  BlackSun(float radius){
    this.radius = radius;
  }
  //----------
  void draw(){
    fill( 128 );
    noStroke();
    directionalLight(255,255,255,1,-1,0.15);
    sphereDetail(24);
    translate( 0,0,-10 );
    sphere(radius);
    translate( 0,0,10 );
    noLights();
  }
}
//------------------------------------------------
//------------------------------------------------