class ForestFire{
  int w, h;
  float[][] heightMap;
  float[][] flammability;
  float[][] fuel;
  float[][] fire, fireChange;
  float step = 0.95;
  float maxHeight = 100;
  float maxFuel = 256;
  float speed = 2.0;
  //------------
  ForestFire(int w, int h){
    this.w = w;
    this.h = h;
    
    // initialize arrays
    heightMap = new float[w][h];
    flammability = new float[w][h];
    fuel = new float[w][h];
    fire = new float[w][h];
    fireChange = new float[w][h];
    
    float offset = random(0,47.11);
    float s = 0.02;
    for(int x=0;x<w;x++)
      for(int y=0;y<h;y++){
        heightMap[x][y] = maxHeight*noise( s*x, s*y, offset+1.7 );
        flammability[x][y] = noise( s*x, s*y, offset );
        fuel[x][y] =  256;
      }
  }
  //------------
  void startFire(int x, int y){
    fire[x][y] += 100;
  }
  //------------
  void modifyTerrain(int mx, int my, float amount){
    for(int x=0;x<w;x++)
      for(int y=0;y<h;y++){
        float d = 0.05*dist(mx,my,x,y);
        float h = amount*exp(-d*d);
        heightMap[x][y] = constrain(heightMap[x][y]+h,0,maxHeight);
      }
  }
  //------------
  void modifyFlammability(int mx, int my, float amount){
    for(int x=0;x<w;x++)
      for(int y=0;y<h;y++){
        float d = 0.05*dist(mx,my,x,y);
        float f = amount*exp(-d*d);
        flammability[x][y] = constrain(flammability[x][y]+f,0,1);
      }
  }
  //------------
  float ignitionProb(int x1, int y1, int x2, int y2){
    float fireFuel = min( fire[x1][y1], fuel[x2][y2] );
    float lowerGround = heightMap[x2][y2] - heightMap[x1][y1];
    return 0.0075*( 3*(flammability[x2][y2]-0.35) + 1*lowerGround );
  }
  //------------
  void update(){
    for(int x=0;x<w;x++)
      for(int y=0;y<h;y++){
        fireChange[x][y] = 0;
      }

    // nearest neighbour map
    int[] nx = {-1,1,0,0,  -1,-1,1,1};
    int[] ny = {0,0,-1,1,  -1,1,-1,1};
    float diff;
    for(int x=1; x<w-1; x++){
      for(int y=1; y<h-1; y++){
        if( fire[x][y] > 0 ){ // fire cell
        
          for(int i=0; i<nx.length; i++){ // loop through the nearest neighbours
            if( random(0,1) < speed*ignitionProb( x, y, x+nx[i], y+ny[i] ) ){
              fireChange[x+nx[i]][y+ny[i]] += speed*10;
            }
          }
          
          if(fuel[x][y] < 2) 
            fire[x][y] = 0;

        }// endif
      }
    }

    for(int x=0; x<w; x++)
      for(int y=0; y<h; y++){
        fire[x][y] += fireChange[x][y];
        if( fire[x][y] > 0 ){
          fire[x][y] += speed*4*(fuel[x][y]/maxFuel - 0.2);
          fuel[x][y] -= speed*fire[x][y]/256;
        }
      }
  }
  //------------
  float posterize(float x){
    return ((int)(8*x))/(float)8;
  }
  //------------
  color getColor(int x, int y){
    colorMode(RGB,255);
    if( fire[x][y]>0 ) return (random(1)<0.5 ? color(255,192,0) : color(255,64,0) );
    colorMode(HSB,1);
    float h = 1-flammability[x][y];
    float s = fuel[x][y]/255;
    float b = (0.25+0.75*fuel[x][y]/maxFuel) * (heightMap[x][y]/(float)maxHeight);
    return color( posterize(h), s, posterize(b) );
    //return color( 0, 255-255*heightMap[x][y]/(float)maxHeight, fuel[x][y] );
  }
  //------------
  void visualize(){
    loadPixels();
    for(int x=0; x<w; x++){
      for(int y=0; y<h; y++){
        pixels[x+w*y] = getColor(x,y);
      }
    }
    updatePixels();
  }
}