//---------------------------------------------
// den globala variabeln som innehåller masspartiklarna
SpaceObject objs;
Star[] stars;
float G;
int pelletCount;
int clickX,clickY;
float rotX, rotY;
float scl;
boolean drawFrameOfReference;
//---------------------------------------------
void setup(){
  size(500,500,P3D);
  framerate(40);
  initStars( 1000 );
  initLagrange();
  drawFrameOfReference = false;
  scl = 1f;
}
//---------------------------------------------
void draw(){

  background(0);

  pushMatrix();

  translate(width/2,width/2,0);
  if(mousePressed){
    rotX += -(mouseY-clickY)*0.0003;
    rotY += (mouseX-clickX)*0.0003;
  }
  rotateX( rotX );
  rotateY( rotY );
  scale(scl,scl,scl);
  
  noFill();
  stroke(64);
  if(drawFrameOfReference) box(300);
  
  
  for( SpaceObject n = objs ; n!=null ; n = n.next )
    n.computeForces();
  for( SpaceObject n = objs ; n!=null ; n = n.next )
    n.update();
  for( SpaceObject n = objs ; n!=null ; n = n.next )
    n.visualize();
    
  for(int i=0;i<stars.length;i++)
    stars[i].visualize();
    
  popMatrix();
  
  translate(0,0,width/2);

}
//---------------------------------------------
void mousePressed(){
  clickX = mouseX;
  clickY = mouseY;
}
//---------------------------------------------
void keyPressed(){
  if(key=='r' || key=='R') drawFrameOfReference = !drawFrameOfReference;
  if(key=='+' || key=='m' || key=='M') scl *= 1.1;
  if(key=='-' || key=='n' || key=='N') scl *= 0.9;
  if(key=='c' || key=='C') initCentralBody();
  if(key=='a' || key=='A') initRandom();
}
//---------------------------------------------
void initCentralBody(){
  G = 0.0011;
  objs = new SpaceObject( 0f,0f,0f,0f,0f,0f, 1000000f, color(255,128,0) );
}
//---------------------------------------------
void initRandom(){
  G = 0.0011;
  float x = random(-200,200);
  float y = random(-200,200);
  float z = random(-200,200);
  float vx = random(-2,2);
  float vy = random(-2,2);
  float vz = random(-2,2);
  colorMode(HSB,100);
  color clr = color(random(0,100),100f,100f);
  colorMode(RGB,255);
  objs.add( new SpaceObject( x,y,z,vx,vy,vz, 25*sq( random(0.5,2f) ), clr ) );
}
//---------------------------------------------
void initLagrange(){
  G = 0.0011;
  objs = new SpaceObject( 0f,0f,0f,0f,0.25,0f, 1000000f, color(255,255,0) );
  objs.add( new SpaceObject( 150f,0f,0f,0f,-2.5f,0f, 100000f, color(0,255,0) ) );
  objs.add( new SpaceObject( 160f,0f,0f,0f,-2.5f,3f, 1f, color(128,128,255) ) );
  objs.add( new SpaceObject( 250f,0f,0f,0f,-2.2f,0f, 1000f, color(255,0,0) ) );
  objs.add( new SpaceObject( -130,0f,0f,0f,0f,2.4f, 1000f, color(255) ) );
}
//---------------------------------------------
void initStars(int n){
  stars = new Star[ n ];
  for(int i=0;i<stars.length;i++)
    stars[i] = new Star( 5000f, color( random(65,148) ) );
}
//---------------------------------------------