//====================================
class Attractor{
  int TRAIL=0, DOTS=1;
  int skipBeginning = 1000;
  int previewDensity = 10;
  float[][] data;
  float[] centerPoint = new float[3];
  float scaleFactor = 7f;
  //-----------------
  void centerPreview(){
    float maxX = -10000f, maxY = -10000f, maxZ = -10000f;
    float minX = 10000f, minY = 10000f, minZ = 10000f;
    for(int i=0;i<data.length;i++){
      maxX = max( maxX, data[i][0] );
      maxY = max( maxY, data[i][1] );
      maxZ = max( maxZ, data[i][2] );
      minX = min( minX, data[i][0] );
      minY = min( minY, data[i][1] );
      minZ = min( minZ, data[i][2] );
    }
    centerPoint = new float[]{ 
      (maxX+minX)/2, (maxY+minY)/2, (maxZ+minZ)/2     };
    scaleFactor = 300f / max( max( maxX-minX, maxY-minY ), maxZ-minZ );
  }
  //-----------------
  void generatePreview(){
  }
  //-----------------
  void drawPreview(){
    drawPreview( DOTS );
  }
  //-----------------
  void renderToBuffer( int batch, ImgBuffer buff ){
  }
  //-----------------
  void drawPreview(int drawMode){
    noFill();
    pushMatrix();
    scale( scaleFactor );
    translate( -centerPoint[0], -centerPoint[1], -centerPoint[2] );

    if(drawMode==DOTS) beginShape( POINTS );
    if(drawMode==TRAIL) beginShape();

    for(int i=0;i<data.length;i++)
      vertex(data[i][0],data[i][1],data[i][2]);

    endShape();

    popMatrix();
  }
  //-----------------
  void setParam(String parameter, float value){
  }
  //-----------------
  float getParam(String parameter){
    return 0f;
  }
}
//====================================
class Lorenz extends Attractor{
  float sigma = 10;
  float rho = 28;
  float beta = 8.0/3.0;
  float step = 0.002;
  //-----------------
  void setParam(String parameter, float value){
    if( parameter.equals("sigma") ) sigma = value;
    if( parameter.equals("rho") ) rho = value;
    if( parameter.equals("beta") ) beta = value;
    if( parameter.equals("step") ) step = value;
  }
  //-----------------
  float getParam(String parameter){
    if( parameter.equals("sigma") ) return sigma;
    if( parameter.equals("rho") ) return rho;
    if( parameter.equals("beta") ) return beta;
    if( parameter.equals("step") ) return step;
    return 0f;
  }
  //-----------------
  void generatePreview(){
    int x=0, y=1, z=2;
    data = new float[5000][3];

    float dx, dy, dz;
    float nx = random(-5,5);
    float ny = random(-5,5);
    float nz = random(-5,5);

    // skip the first part of the preview trail
    for(int j=0;j<skipBeginning;j++){
      dx = 8*step * ( sigma*(ny-nx) );
      dy = 8*step * ( nx*(rho-nz) - ny );
      dz = 8*step * ( nx*ny - beta*nz );
      nx += dx;
      ny += dy;
      nz += dz;
    }

    // store beginning of preview trail
    data[0] = new float[]{ 
      nx, ny, nz        };

    for(int i=1;i<data.length;i++){
      //float stepV = step + random(-step/4,step/4);
      nx = data[i-1][x];
      ny = data[i-1][y];
      nz = data[i-1][z];

      // calculate unvisualized parts of the preview trail
      for(int j=0;j<previewDensity;j++){
        dx = step * ( sigma*(ny-nx) );
        dy = step * ( nx*(rho-nz) - ny );
        dz = step * ( nx*ny - beta*nz );
        nx += dx;
        ny += dy;
        nz += dz;
      }

      // store parts of the preview trail that should be visible
      data[i][x] = nx;
      data[i][y] = ny;
      data[i][z] = nz;
    }
  }
  //-----------------
  void renderToBuffer( int batch, ImgBuffer buff ){
    pushMatrix();
    scale( scaleFactor );
    translate( -centerPoint[0], -centerPoint[1], -centerPoint[2] );

    float dx, dy, dz;
    float x = random(-5,5);
    float y = random(-5,5);
    float z = random(-5,5);

    // skip the first part of the preview trail
    for(int j=0;j<skipBeginning;j++){
      dx = 8*step * ( sigma*(y-x) );
      dy = 8*step * ( x*(rho-z) - y );
      dz = 8*step * ( x*y - beta*z );
      x += dx;
      y += dy;
      z += dz;
    }

    for(int i=1;i<batch;i++){
      dx = step * ( sigma*(y-x) );
      dy = step * ( x*(rho-z) - y );
      dz = step * ( x*y - beta*z );
      x += dx;
      y += dy;
      z += dz;
      buff.drawPoint(screenX(x,y,z),screenY(x,y,z));
    }
    
    popMatrix();
  }
}
//====================================