class ImgBuffer{
  int[][] imgBuffer;
  boolean antialias = false;
  color[] spectrum;
  //-----------------
  ImgBuffer( int w, int h ){
    imgBuffer = new int[w][h];

    spectrum = new color[2000];

    int[] spec = new int[]{ 
      128,255,64     };
    float sLen = (float)spectrum.length;

    for(int i=0;i<spectrum.length;i++)
      spectrum[i] = color( i*spec[0]/sLen, i*spec[1]/sLen, i*spec[2]/sLen );
  }
  //-----------------
  void clearBuffer(){
    for(int x=0;x<imgBuffer.length;x++)
      for(int y=0;y<imgBuffer[0].length;y++)
        imgBuffer[x][y] = 0;
  }
  //-----------------
  void drawBuffer(){
    
    int maxVal=0;
    for(int x=0;x<imgBuffer.length;x++)
      for(int y=0;y<imgBuffer[0].length;y++)
        maxVal = max( maxVal, imgBuffer[x][y] );
    
    int sLen = spectrum.length - 1;
    float colCoef = 32f * spectrum.length / ( (float)maxVal ) / sLen;
    
    loadPixels();
    for(int x=0;x<imgBuffer.length;x++)
      for(int y=0;y<imgBuffer[0].length;y++)
        pixels[x+y*width] = spectrum[ sLen - (int)(sLen/(1+colCoef*imgBuffer[x][y] )) ];
    updatePixels();
    
  }
  //-----------------
  void drawPoint(float x, float y){
    if(antialias){
      int sx = (int)x;
      int sy = (int)y;
      if( sx<=0 || sx>=width-2) return;
      if( sy<=0 || sy>=height-2) return;
      float xP = x-(int)x;
      float yP = y-(int)y;
      float xN = 1-xP;
      float yN = 1-xP;
      imgBuffer[sx  ][sy  ] += (int)(64*xN*yN);
      imgBuffer[sx+1][sy  ] += (int)(64*xP*yN);
      imgBuffer[sx  ][sy+1] += (int)(64*xN*yP);
      imgBuffer[sx+1][sy+1] += (int)(64*xP*yP);
    } 
    else{
      int sx = (int)x;
      int sy = (int)y;
      if( sx<=0 || sx>=width-2) return;
      if( sy<=0 || sy>=height-2) return;
      imgBuffer[ sx ][ sy ]+=1;
    }
  }
}