//####################################################################################################
// skanaarGUI : Graphical User Interface Components
// one day this GUI will be released with a proper documentation
//####################################################################################################
class GuiGizmo {
  String id;
  SkanaarGUI parent;
  int x,y,w,h,cb;
  //----------------------
  boolean mouseIsInside(int mx, int my){ 
    return (mx>=x-cb && mx<=x+w+cb && my>=y-cb && my<=y+h+cb) ;
  }
  String mouseInput(int mx, int my){ 
    return null ;
  }
  String keyInput(char k){ 
    return null ;
  }
  void mouseHover(int mx, int my){
  }
  void mouseDrag(int mx, int my){
  }
  void visualize(){
  }
  SkanaarGUI layer(String id){
    return null;
  }
  void move(int tx, int ty){
    this.x += tx;
    this.y += ty;
  }
  float getValue(String slid){
    return 0f;
  }
  String getText(String textinput){
    return null;
  }
  void showLayer(String id){
  }
  void hideLayer(String id){
  }
  void toggleLayer(String id){
  }
}
//####################################################################################################
class SkanaarGUI extends GuiGizmo {
color cSlidBar = #888888, cSlidStroke = #BBBBBB, cSlidBack = #444444;
color cSlidBarHover = #BBBBBB, cSlidStrokeHover = #FFFFFF, cSlidBackHover = #444444;
color cButtStroke = #BBBBBB, cButtFill = #444444, cButtText = #BBBBBB;
color cButtStrokeHover = #FFFFFF, cButtFillHover = #444444, cButtTextHover = #FFFFFF;
color cTextinputStroke = #BBBBBB, cTextinputFill = #888888, cTextinputText = #333333;
color cTextinputStrokeHover = #FFFFFF, cTextinputFillHover = #888888, cTextinputTextHover = #000000;
color cRectStroke = #FFFFFF, cRectFill = #666666;
color cText = #FFFFFF;
  GuiGizmo[] gizmos;
  int buttonWidth=60, buttonHeight=15, sliderWidth=5, textinputHeight=13, textinputMargin=3;
  PFont font;
  boolean visible;
  //----------------------
  SkanaarGUI(){ 
    id = "gui_main";
    gizmos = new GuiGizmo[0];
    visible = true;
  }
  //----------------------
  SkanaarGUI(String name){ 
    id = name;
    gizmos = new GuiGizmo[0];
    visible = true;
  }
  //----------------------
  void setDesign(PFont font){
    this.font = font;
  }
  //----------------------
  void moveLayer(int x, int y){
    for(int i=0;i<gizmos.length;i++) gizmos[i].move(x,y);
  }
  //----------------------
  boolean mouseIsInside(int x, int y){
    return true;
  }
  //----------------------
  void addRect(String id, int x, int y, int w, int h){
    GuiGizmo[] temp = new GuiGizmo[gizmos.length+1];
    for(int i=0;i<gizmos.length;i++) temp[i] = gizmos[i];
    temp[gizmos.length] = new Rect(id, this, x, y, w, h);
    gizmos = temp;
    if(x < this.x) this.x = x;
    if(y < this.y) this.y = y;
    if(this.x+this.w < x+w) this.w = x+w-this.x;
    if(this.y+this.h < y+h) this.h = y+h-this.y;
  }
  //----------------------
  void addText(String id, String txt, int ALIGN, int x, int y, int w, int h){
    GuiGizmo[] temp = new GuiGizmo[gizmos.length+1];
    for(int i=0;i<gizmos.length;i++) temp[i] = gizmos[i];
    temp[gizmos.length] = new Text(id, this, txt, ALIGN, x, y, w, h);
    gizmos = temp;
  }
  //----------------------
  void addText(String id, String txt, int x, int y){
    GuiGizmo[] temp = new GuiGizmo[gizmos.length+1];
    for(int i=0;i<gizmos.length;i++) temp[i] = gizmos[i];
    temp[gizmos.length] = new Text(id, this, txt, LEFT, x, y, 1000, 1000);
    gizmos = temp;
  }
  //----------------------
  void addButton(String id, String caption, int x, int y){
    GuiGizmo[] temp = new GuiGizmo[gizmos.length+1];
    for(int i=0;i<gizmos.length;i++) temp[i] = gizmos[i];
    temp[gizmos.length] = new Button(id, this, x, y, caption);
    gizmos = temp;
  }
  //----------------------
  void addSliderH(String id, int x, int y, int w, float value){
    GuiGizmo[] temp = new GuiGizmo[gizmos.length+1];
    for(int i=0;i<gizmos.length;i++) temp[i] = gizmos[i];
    temp[gizmos.length] = new SliderH(id, this, x, y, w, value);
    gizmos = temp;
  }
  //----------------------
  void addSliderV(String id, int x, int y, int w, float value){
    GuiGizmo[] temp = new GuiGizmo[gizmos.length+1];
    for(int i=0;i<gizmos.length;i++) temp[i] = gizmos[i];
    temp[gizmos.length] = new SliderV(id, this, x, y, w, value);
    gizmos = temp;
  }
  //----------------------
  void addTextinput(String id, int x, int y, int w, String content){
    GuiGizmo[] temp = new GuiGizmo[gizmos.length+1];
    for(int i=0;i<gizmos.length;i++) temp[i] = gizmos[i];
    temp[gizmos.length] = new Textinput(id, this, x, y, w, content);
    gizmos = temp;
  }
  //----------------------
  void addLayer(String id){
    GuiGizmo[] temp = new GuiGizmo[gizmos.length+1];
    for(int i=0;i<gizmos.length;i++) temp[i+1] = gizmos[i];
    temp[0] = new SkanaarGUI(id);
    ((SkanaarGUI) temp[0]).setDesign(font);
    gizmos = temp;
  }
  //----------------------
  SkanaarGUI layer(String id){
    for(int i=0;i<gizmos.length;i++) if(gizmos[i].id.equals(id)) return (SkanaarGUI) gizmos[i];
    return null;
  }
  //----------------------
  float getValue(String slid){
    for(int i=0;i<gizmos.length;i++) if(gizmos[i].id.equals(slid)) return gizmos[i].getValue(slid);
    return 0f;
  }
  //----------------------
  String getText(String id){
    for(int i=0;i<gizmos.length;i++) if(gizmos[i].getText(id) != null) return gizmos[i].getText(id);
    return null;
  }
  //----------------------
  void showLayer(String id){
    if(this.id.equals(id)) visible = true;
    for(int i=0;i<gizmos.length;i++) if(gizmos[i].id.equals(id)) gizmos[i].showLayer(id);
  }
  //----------------------
  void hideLayer(String id){
    if(this.id.equals(id)) visible = false;
    for(int i=0;i<gizmos.length;i++) if(gizmos[i].id.equals(id)) gizmos[i].hideLayer(id);
  }
  //----------------------
  void toggleLayer(String id){
    if(this.id.equals(id)) visible = !visible;
    for(int i=0;i<gizmos.length;i++) if(gizmos[i].id.equals(id)) gizmos[i].toggleLayer(id);
  }
  //----------------------
  void visualize(){
    if(visible) for(int i=gizmos.length-1;i>=0;i--) gizmos[i].visualize();
  }
  //----------------------
  String mouseInput(int mx, int my){
    String response = null;
    if(visible) for(int i=0;i<gizmos.length;i++){
      if(gizmos[i].mouseIsInside(mx,my)) response = gizmos[i].mouseInput(mx,my);
      if(response!=null) return response;
    }
    return null ;
  }
  //----------------------
  void mouseDrag(int mx, int my){
    for(int i=0;i<gizmos.length;i++){
      if(gizmos[i].mouseIsInside(mx,my)) gizmos[i].mouseDrag(mx,my);
    }
  }
  //----------------------
  String keyInput(char k){
    String gizmo = null;
    if(visible) for(int i=0;i<gizmos.length;i++){
      gizmo = gizmos[i].keyInput(k);
      if(gizmo!=null) return gizmo;
    }
    return null ;
  }
  //----------------------
  void mouseHover(int mx, int my){
  }
  //----------------------
  void setColors(int mx, int my){
  }
}
//####################################################################################################
class SliderH extends GuiGizmo{
  float value;
  //----------------------
  SliderH(String id, SkanaarGUI parent, int x, int y, int w, float value) {
    this.id = id;
    this.parent = parent;
    this.x = x;
    this.y = y;
    this.w = w;
    this.h = parent.sliderWidth;
    this.value = value;
    cb = 2;
  }
  //----------------------
  void visualize() {
    if(mouseIsInside(mouseX,mouseY)){
      fill(parent.cSlidBackHover);
      stroke(parent.cSlidStrokeHover);
      rect(x,y,w,h);
      fill(parent.cSlidBarHover);
      rect(x,y,w*value,h );
    } 
    else {
      fill(parent.cSlidBack);
      stroke(parent.cSlidStroke);
      rect(x,y,w,h);
      fill(parent.cSlidBar);
      rect(x,y,w*value,h );
    }
  }
  //----------------------
  String mouseInput(int mx, int my) {
    if(mx>=x-cb && mx<=x+w+cb && my>=y-cb && my<=y+h+cb){
      value = constrain( (mx-x)/(float)w , 0, 1) ;
    }
    return id;
  }
  //----------------------
  void mouseDrag(int mx, int my) {
    mouseInput(mx,my);
  }
  //----------------------
  float getValue(String a) {
    return value;
  }
}
//####################################################################################################
class SliderV extends GuiGizmo{
  float value;
  //----------------------
  SliderV(String id, SkanaarGUI parent, int x, int y, int h, float value) {
    this.id = id;
    this.parent = parent;
    this.x = x;
    this.y = y;
    this.w = parent.sliderWidth;
    this.h = h;
    this.value = value;
    cb = 2;
  }
  //----------------------
  void visualize() {
    if(mouseIsInside(mouseX,mouseY)){
      fill(parent.cSlidBackHover);
      stroke(parent.cSlidStrokeHover);
      rect(x,y,w,h);
      fill(parent.cSlidBarHover);
      rect(x,y,w*value,h );
    } 
    else {
      fill(parent.cSlidBack);
      stroke(parent.cSlidStroke);
      rect(x,y,w,h);
      fill(parent.cSlidBar);
      rect(x,y,w*value,h );
    }
  }
  //----------------------
  String mouseInput(int mx, int my) {
    if(mx>=x-cb && mx<=x+w+cb && my>=y-cb && my<=y+h+cb){
      value = constrain( (h-my+y)/h , 0, 1) ;
    }
    return id;
  }
  //----------------------
  void mouseDrag(int mx, int my) {
    mouseInput(mx,my);
  }
  //----------------------
  float getValue(String a) {
    return value;
  }
}
//####################################################################################################
class Button extends GuiGizmo{
  String caption;
  //----------------------
  Button(String id, SkanaarGUI parent, int x, int y, String caption) {
    this.id = id;
    this.parent = parent;
    this.x = x;
    this.y = y;
    this.w = parent.buttonWidth;
    this.h = parent.buttonHeight;
    this.caption = caption;
  }
  //----------------------
  void visualize() {
    if(mouseIsInside(mouseX,mouseY)){
      fill(parent.cButtFillHover);
      stroke(parent.cButtStrokeHover);
      rect(x,y,w,h);
      fill(parent.cButtTextHover);
      textFont(parent.font);
      textAlign(CENTER);
      text(caption,x+w/2,y+h/2+4);
    } 
    else {
      fill(parent.cButtFill);
      stroke(parent.cButtStroke);
      rect(x,y,w,h);
      fill(parent.cButtText);
      textFont(parent.font);
      textAlign(CENTER);
      text(caption,x+w/2,y+h/2+4);
    }
  }
  //----------------------
  String mouseInput(int mx, int my) {
    if(mx>x-cb && mx<x+w+cb && my>y && my<y+h) return id;
    return null;
  }
}
//####################################################################################################
class Rect extends GuiGizmo{
  //----------------------
  Rect(String id, SkanaarGUI parent, int x, int y, int w, int h) {
    this.id = id;
    this.parent = parent;
    this.x = x;
    this.y = y;
    this.w = w;
    this.h = h;
  }
  //----------------------
  void visualize() {
      fill(parent.cRectFill);
      stroke(parent.cRectStroke);
      rect(x,y,w,h);
  }
  //----------------------
  String mouseInput(int mx, int my) {
    if(mx>x-cb && mx<x+w+cb && my>y && my<y+h) return id;
    return null;
  }
}
//####################################################################################################
class Text extends GuiGizmo{
  String txt;
  int ALIGN;
  //----------------------
  Text(String id, SkanaarGUI parent, String txt, int ALIGN, int x, int y, int w, int h) {
    this.id = id;
    this.parent = parent;
    this.x = x;
    this.y = y;
    this.w = w;
    this.h = h;
    this.txt = txt;
    this.ALIGN = ALIGN;
  }
  //----------------------
  void visualize() {
      fill(parent.cText);
      textAlign(ALIGN);
      textFont( parent.font );
      text(txt,x,y,w,h);
  }
}
//####################################################################################################
class Textinput extends GuiGizmo{
  String content;
  int margin;
  //----------------------
  Textinput(String id, SkanaarGUI parent, int x, int y, int w, String content) {
    this.id = id;
    this.parent = parent;
    this.x = x;
    this.y = y;
    this.w = w;
    this.h = parent.textinputHeight;
    this.content = content;
    margin = parent.textinputMargin;
  }
  //----------------------
  void visualize() {
    if(mouseIsInside(mouseX,mouseY)){
      fill(parent.cTextinputFillHover);
      stroke(parent.cTextinputStrokeHover);
      rect(x,y,w,h);
      fill(parent.cTextinputTextHover);
      textFont(parent.font);
      textAlign(LEFT);
      text(content,x+margin,y+h-margin);
      if(millis()%1000<500) line(x+margin+textWidth(content)+2,y+h-margin,x+margin+textWidth(content)+5,y+h-margin);
    } 
    else {
      fill(parent.cTextinputFill);
      stroke(parent.cTextinputStroke);
      rect(x,y,w,h);
      fill(parent.cTextinputText);
      textFont(parent.font);
      textAlign(LEFT);
      text(content,x+margin,y+h-margin);
      if(millis()%1000<500) line(x+margin+textWidth(content)+2,y+h-margin,x+margin+textWidth(content)+5,y+h-margin);
    }
  }
  //----------------------
  String keyInput(char k) {
    switch(k){
    case 8:
      if(content.length()>0){
        content = content.substring(0,content.length()-1);
      }
      break;
    case 13:  // Avoid special keys
    case 10:
    case 65535:
    case 127:
    case 27:
      break;
    default:
      if(textWidth(content+k)>w-margin) return null;
      content=content+k;
      break;
    }
    return null;
  }
  //----------------------
  String getText(String id) {
    if(this.id.equals(id)) return content;
    return null;
  }
}
//#####################################################################