color[] spectrum;
double scle = 3.0;
double xoff = -2.0;
double yoff = -2.0;
int maxIter = 64, res = 1;
Slider maxIterSlider;
Slider resSlider;
//------------------------------------------------
void setup() {

  size(400,400);
  maxIterSlider = new Slider(width-15,10,5,height-20,16f,512f, (float) maxIter);
  resSlider = new Slider(width-25,height-110,5,100,4f,0f, (float)res);
  spectrum = loadSpectrum("chlorophyll");

  noLoop();
  redraw();
}
//------------------------------------------------
void draw() {
  background(0);
  drawMbrot(0,255,0);
  maxIterSlider.visualize();
  resSlider.visualize();
}
//------------------------------------------------
color[] loadSpectrum(String name) {
  PImage img = loadImage("spectrum-"+name+".jpg");
  color[] spectrum = new color[img.width];
  for( int i=0 ; i<img.width ; i++){
    spectrum[i] = img.get(i,0);
  }
  return spectrum;
}
//------------------------------------------------
void mouseReleased() {
  maxIter = (int)maxIterSlider.mouseInput(mouseX,mouseY);
  res = (int) pow( 2 , (int) (resSlider.mouseInput(mouseX,mouseY)-1) );

  if(mouseX>10 && mouseX<width-30 && mouseY>10 && mouseY<height-10){
    float zoom = 1f;
    if(mouseButton == LEFT) zoom = 0.5;
    if(mouseButton == RIGHT) zoom = 2f;
    xoff = -0.5*zoom*scle + xoff + mouseX*scle/ (float) width;
    yoff = -0.5*zoom*scle + yoff + mouseY*scle/ (float) height;
    scle = scle*zoom;
  }
  redraw();
}
//------------------------------------------------
void drawMbrot(int r, int g, int b) {

  double re, im, cFactor, logMax = log( maxIter );
  int iterations;
  loadPixels();

  for(int x=0 ; x<width ; x+=res ){
    for(int y=0 ; y<width ; y+=res ){

      re = xoff + x*scle/ (double) width;
      im = yoff + y*scle/ (double) height;

      iterations = evalPoint(re,im);
      if(res == 1){
        pixels[x+width*y] = spectrum[ (int) 255*iterations/maxIter ];
      } 
      else {
        for(int q=0 ; q<res ; q++ ){
          for(int w=0 ; w<res ; w++ ){
            pixels[x+q+width*(y+w)] = spectrum[ (int) 255*iterations/maxIter ];
          }
        }
      }
    }
  }

  updatePixels();
}
//------------------------------------------------
int evalPoint(double a, double b) {

  double x=0f,y=0f,re,im;
  int iteration = 0;
  while ( x*x + y*y < 16  &&  iteration < maxIter ) {
    re = x*x - y*y + a;
    im = 2*x*y + b;
    x = re;
    y = im;
    iteration++;
  }
  return iteration;
}