//#########################
class CheckPoint{
  float x,y,radius,drawSize;
  int spawnTimer, spawnDuration;
  Car car1, car2;
  //-----------------------
  CheckPoint(Car c1, Car c2){
    x = -20000;
    y = -20000;
    car1 = c1;
    car2 = c2;
    radius = 10;
    spawnTimer = 0;
    spawnDuration = 10;
    respawn();
  }
  //-----------------------
  void update(){
    if(spawnTimer == 0){
      if( dist(x,y,car1.x,car1.y)<radius ) capture(car1);
      if( dist(x,y,car2.x,car2.y)<radius ) capture(car2);
    }
    else{
      spawnTimer--;
      if(spawnTimer == spawnDuration) randPosQuad();
    }
    drawSize = abs(spawnTimer-spawnDuration);
  }
  //-----------------------
  void visualize(){
    pushMatrix();
    translate(x,y,10);
    fill(255,128,128);
    sphere( drawSize );
    fill(192,192,192);
    translate(0,0,-10);
    ellipse(0,0,2*drawSize,2*drawSize);
    popMatrix();
  }
  //-----------------------
  void capture(Car car){
    car.giveScore();
    respawn();
  }
  //-----------------------
  void respawn(){
    spawnTimer = spawnDuration*2;
  }
  //-----------------------
  void randPosCircular(){
    float angle = random(TWO_PI);
    float r = random(0.1*mx,0.5*mx);
    x = mx+r*cos(angle);
    y = my*1.2+r*sin(angle);
  }
  //-----------------------
  void randPosQuad(){
    float xamt = random(1);
    float yamt = random(1);
    float tx = lerp(65,230,xamt);
    float bx = lerp(110,185,xamt);
    x = lerp(tx,bx,yamt);
    y = lerp(80,255,yamt);
  }
}
//#########################