//==========================================
class Player{
  color[] imgBuffer;
  float[][] distort;
  int pixelsWidth;
  int pixelsHeight;
  float viewWidth;
  float viewHeight;
  float[] pos;
  float[] vel;
  float[] dir;
  float[] up;
  float[] left;
  Room currentRoom;
  int x=0,y=1,z=2;
  //------------
  Player(Room cRoom){
    loadPixels();
    imgBuffer = new color[width*height];
    pixelsWidth = width;
    pixelsHeight = height;
    viewWidth = 2f;
    viewHeight = 1.2f;
    pos = vector(0,80,80);
    vel = vector(0,0,0);
    dir = vector(0,0,-1);
    up  = vector(0,-1,0);
    left= vector(-1,0,0);
    currentRoom = cRoom;

    distort = new float[width][height];
    for( int i=0 ; i<pixelsWidth ; i++ )
      for( int j=0 ; j<pixelsHeight ; j++ ){
        float canvasX =  -viewWidth*(i-pixelsWidth/2)/(float)pixelsWidth;
        float canvasY =  -viewHeight*(j-pixelsHeight/2)/(float)pixelsHeight;
        float rayX = dir[x] + canvasX*left[x] + canvasY*up[x];
        float rayY = dir[y] + canvasX*left[y] + canvasY*up[y];
        float rayZ = dir[z] + canvasX*left[z] + canvasY*up[z];
        distort[i][j] = 1f / mag( rayX,rayY,rayZ );
      }
  }
  //------------
  void update(){

    userInput();

    checkForRoom();
    
    int halfW = pixelsWidth>>1;
    int halfH = pixelsHeight>>1;
    float factorW = -viewWidth/(float)pixelsWidth;
    float factorH = -viewHeight/(float)pixelsHeight;
    
    //mark walls as visible/invisible
    //float[] ray1 = vector( dir[x]-viewWidth*0.5*left[x]-viewHeight*0.5*up[x] );
    //currentRoom.imprintFrustrumOnWalls();

    for( int i=0 ; i<pixelsWidth ; i++ ){
      float canvasX =  factorW*(i-halfW);
      for( int j=0 ; j<pixelsHeight ; j++ ){
        float canvasY =  factorH*(j-halfH);
        float rayX = dir[x] + canvasX*left[x] + canvasY*up[x];
        float rayY = dir[y] + canvasX*left[y] + canvasY*up[y];
        float rayZ = dir[z] + canvasX*left[z] + canvasY*up[z];
        float d = distort[i][j];
        color c = currentRoom.castRay( pos[x], pos[y], pos[z], rayX*d, rayY*d, rayZ*d );
        imgBuffer[i+j*pixelsWidth] = c ;
      }
    }

    arraycopy(imgBuffer,pixels);
  }
  //-----------------
  void userInput(){
    float a = 0.05;
    if(sk.keyDown('s')){
      dir = vector( a*up[0]+dir[0], a*up[1]+dir[1], a*up[2]+dir[2] );
      up = vector( up[0]-a*dir[0], up[1]-a*dir[1], up[2]-a*dir[2] );
    }
    if(sk.keyDown('w')){
      dir = vector( -a*up[0]+dir[0], -a*up[1]+dir[1], -a*up[2]+dir[2] );
      up = vector( up[0]+a*dir[0], up[1]+a*dir[1], up[2]+a*dir[2] );
    }
    if(sk.keyDown('d')){
      dir = vector( -a*left[0]+dir[0], -a*left[1]+dir[1], -a*left[2]+dir[2] );
      left = vector( left[0]+a*dir[0], left[1]+a*dir[1], left[2]+a*dir[2] );
    }
    if(sk.keyDown('a')){
      dir = vector( a*left[0]+dir[0], a*left[1]+dir[1], a*left[2]+dir[2] );
      left = vector( left[0]-a*dir[0], left[1]-a*dir[1], left[2]-a*dir[2] );
    }

    float d = mag( dir[0],dir[1],dir[2] );
    float u = mag( up[0],up[1],up[2] );
    float l = mag( left[0],left[1],left[2] );
    dir = vector(dir[0]/d,dir[1]/d,dir[2]/d);
    up = vector(up[0]/u,up[1]/u,up[2]/u);
    left = vector(left[0]/l,left[1]/l,left[2]/l);

    float speed = 2f;
    if(mousePressed) pos = vector( pos[0]+speed*dir[0], pos[1]+speed*dir[1], pos[2]+speed*dir[2] );
  }
  //-----------------
  void checkForRoom(){

    for( int i=0 ; i<currentRoom.walls.length ; i++ )
      if(currentRoom.walls[i].isPortal){
        Wall w = currentRoom.walls[i];
        float dot = w.nx*(pos[0]-w.wx) + w.ny*(pos[1]-w.wy) + w.nz*(pos[2]-w.wz);
        if( dot<0f ){
          currentRoom = w.adjecentRoom;
          break;
        }
      }

  }
  //-----------------
}