//==========================
class Enemy extends Entity{
  String name;
  int health, attack, cycleValue, memoryValue;
  int gridx, gridy;
  float vx, vy, speed;
  boolean isWallBreaker;
  //---------------
  Enemy(String type){
    isEnemy = true;
    isDamageable = true;
    fillColor = color(255,0,0,128);
    polyStrokeColor = color(255,64,64,192);
    lineStrokeColor = color(255,0,0,192);
    loadEnemy(type);
  }
  //---------------
  Enemy(int enemyIndex, int gridx, int gridy){
    this.x = game.terrain.xPos(gridx);
    this.y = game.terrain.yPos(gridy);
    this.fxZ = 5;
    this.gridx = gridx;
    this.gridy = gridy;
    isEnemy = true;
    isDamageable = true;
    fillColor = color(255,0,0,128);
    polyStrokeColor = color(255,64,64,192);
    lineStrokeColor = color(255,0,0,192);
    loadEnemy( enemyIndex );
  }
  //---------------
  void inflictDamage( int d ){
    health -= d;
    if(health<=0){
      kill();
      game.rewardResources(cycleValue, memoryValue);
    }
  }
  //---------------
  void inflictDeath(){
    inflictDamage( 2*health );
  }
  //---------------
  void kill(){
    super.kill();
    game.objs.add( new Death(this) );
  }
  //---------------
  void breakWall(int tx, int ty ){
    kill();
    game.objs.add( new Deletion(tx,ty) );
    if( game.terrain.groundEntity[tx][ty] != null) game.terrain.groundEntity[tx][ty].kill();
    game.terrain.groundEntity[tx][ty] = null;
    game.terrain.isPath[tx][ty] = true;
    game.terrain.calculateAIPath();
  }
  //---------------
  void loadEnemy(String filename){
    String[] file = loadStrings("enemies/"+filename+".txt");
    for(int i=0 ; i<file.length ; i++){
      String[] tmp = split( file[i] , ':' );
      if( tmp[0].equals("name") ) name = trim(tmp[1]);
      if( tmp[0].equals("geometry") ) setGeometry( trim(tmp[1]) );
      if( tmp[0].equals("attack") ) attack = Integer.parseInt( trim(tmp[1]) );
      if( tmp[0].equals("health") ) health = Integer.parseInt( trim(tmp[1]) );
      if( tmp[0].equals("speed") ) speed = Float.parseFloat( trim(tmp[1]) );
      if( tmp[0].equals("cyclevalue") ) cycleValue = Integer.parseInt( trim(tmp[1]) );
      if( tmp[0].equals("memoryvalue") ) memoryValue = Integer.parseInt( trim(tmp[1]) );
      if( tmp[0].equals("isWallBreaker") ) isWallBreaker = true;
    }
  }
  //---------------
  void loadEnemy(int enemyIndex){
    name = game.mediabank.enemyTemplates[enemyIndex].name;
    geometry = game.mediabank.enemyTemplates[enemyIndex].geometry;
    attack = game.mediabank.enemyTemplates[enemyIndex].attack;
    health = game.mediabank.enemyTemplates[enemyIndex].health;
    speed = game.mediabank.enemyTemplates[enemyIndex].speed;
    cycleValue = game.mediabank.enemyTemplates[enemyIndex].cycleValue;
    memoryValue = game.mediabank.enemyTemplates[enemyIndex].memoryValue;
    isWallBreaker = game.mediabank.enemyTemplates[enemyIndex].isWallBreaker;
  }
  //---------------
  void corruptCPU(int tx, int ty ){
    CPU c = (CPU) game.terrain.groundEntity[tx][ty];
    if(c!=null){
      c.inflictDamage(attack);
      kill();
      game.terrain.calculateAIPath();
      game.objs.add( new Deletion(tx,ty) );
    }
  }
  //---------------
  void update(){
    // the "walk" methods sets the target grid-cell
    if(isWallBreaker)
      wallBreakerWalk();
    else
      walk();

    // set velocity towards target
    vx = constrain( 0.1*(game.terrain.xPos(gridx) - x) , -speed , speed );
    vy = constrain( 0.1*(game.terrain.yPos(gridy) - y) , -speed , speed );
    x += vx;
    y += vy;
  }
  //---------------
  int minDist(int[][] cpuD, int tx, int ty){
    int minDist = cpuD[tx][ty];
    minDist = min( cpuD[tx+1][ty], minDist );
    minDist = min( cpuD[tx-1][ty], minDist );
    minDist = min( cpuD[tx][ty+1], minDist );
    minDist = min( cpuD[tx][ty-1], minDist );
    return minDist;
  }
  //---------------
  void walk(){
    int[][] cpuD = game.terrain.CPUDist;

    // find distance to closest path-segment
    int minDist = minDist(cpuD,gridx,gridy);

    // if enemy has reached its target cell
    if( dist(x,y,game.terrain.xPos(gridx),game.terrain.yPos(gridy)) < game.terrain.cellSize/4 ){
      if( game.terrain.isCPU[gridx][gridy] ) corruptCPU(gridx,gridy);
      // set closest path-segment to target (gridx,gridy)
      else if( cpuD[gridx+1][gridy] == minDist ) gridx++;
      else if( cpuD[gridx-1][gridy] == minDist ) gridx--;
      else if( cpuD[gridx][gridy+1] == minDist ) gridy++;
      else if( cpuD[gridx][gridy-1] == minDist ) gridy--;
    }
  }
  //---------------
  void wallBreakerWalk(){
    int[][] cpuD = game.terrain.wallBreakerCPUDist;

    // find distance to closest path-segment
    int minDist = minDist( cpuD, gridx, gridy );

    // if enemy has reached its target cell
    if( dist(x,y,game.terrain.xPos(gridx),game.terrain.yPos(gridy)) < game.terrain.cellSize/4 ){
      if( !game.terrain.isPath[gridx][gridy] ) breakWall(gridx,gridy);
      else if( game.terrain.isCPU[gridx][gridy] ) corruptCPU(gridx,gridy);
      // set closest path-segment to target (gridx,gridy)
      else if( cpuD[gridx+1][gridy] == minDist ) gridx++;
      else if( cpuD[gridx-1][gridy] == minDist ) gridx--;
      else if( cpuD[gridx][gridy+1] == minDist ) gridy++;
      else if( cpuD[gridx][gridy-1] == minDist ) gridy--;
    }
  }
  //---------------
  void visualize(){
    geometry.visualize(x,y,z,0f,0f,-HALF_PI + atan2(vy,vx));
  }
}