//==========================
class EntityList{
  Vector objs;
  int length;
  //---------------
  EntityList(){
    objs = new Vector();
  }
  //---------------
  Entity get(int i){
    return (Entity) objs.elementAt(i);
  }
  //---------------
  void add(Entity e){
    objs.addElement( e );
    length = objs.size();
  }
  //---------------
  void updateAll(){
    for(int i=0;i<objs.size();i++){
      ( (Entity) objs.elementAt(i) ).update();
      if( ( (Entity) objs.elementAt(i) ).killMe ){
        objs.removeElementAt(i);
        i--;
        length = objs.size();
      }
    }
  }
  //---------------
  Enemy getEnemyAtPoint(float x, float y){
    Entity closest = null;
    float minDist = 100000;

    for(int i=0;i<objs.size();i++){
      Entity e = (Entity) objs.elementAt(i);
      if( e.isEnemy )
        if( dist(x,y,e.x,e.y) < minDist ){
          minDist = dist(x,y,e.x,e.y);
          closest = e;
        }
    }

    if(closest == null || minDist>game.terrain.cellSize)
      return null;
    else
      return (Enemy) closest;
  }
  //---------------
  Defense getDefenseAtPoint(float x, float y){
    Entity closest = null;
    float minDist = 100000;

    for(int i=0;i<objs.size();i++){
      Entity e = (Entity) objs.elementAt(i);
      if( e.isDefense )
        if( dist(x,y,e.x,e.y) < minDist ){
          minDist = dist(x,y,e.x,e.y);
          closest = e;
        }
    }

    if(closest == null || minDist>game.terrain.cellSize)
      return null;
    else
      return (Defense) closest;
  }
  //---------------
  void visualizeAll(){
    for(int i=0;i<objs.size();i++)
      ( (Entity) objs.elementAt(i) ).visualize();
  }
}
//==========================
class Entity{
  float x,y,z;
  float fxX,fxY,fxZ;
  boolean killMe;
  boolean isCPU, isEnemy, isDefense, isMarker, isDamageable, isInvulnerable, isSpawnpoint;
  color fillColor,polyStrokeColor, lineStrokeColor;
  Description description;
  Geometry geometry;
  //---------------
  Description getDescription(){
    return new Description();
  }
  //---------------
  void inflictDamage( int d ){
  }
  //---------------
  void kill(){
    killMe = true;
  }
  //---------------
  void update(){
  }
  //---------------
  void visualize(){
    geometry.visualize(x,y,z,0f,0f,0f);
  }
  //---------------
  void setGeometry(String s){
    geometry = game.mediabank.getGeometry(s);
    geometry.lineStrokeColor = lineStrokeColor;
    geometry.polyStrokeColor = polyStrokeColor;
    geometry.fillColor = fillColor;
  }
}
//==========================
class Geometry{
  float fxX,fxY,fxZ;
  float scl;
  int[][][] lines;
  int[][][] polys;
  color fillColor,polyStrokeColor, lineStrokeColor;
  //---------------
  Geometry( String filename ){
    loadGeometry( filename );
  }
  //---------------
  void visualize(float x, float y, float z, float rotx, float roty, float rotz){
    fill(fillColor);
    stroke(polyStrokeColor);

    pushMatrix();
    translate(x,y,z);
    rotateX(rotx);
    rotateY(roty);
    rotateZ(rotz);

    for(int i=0;i<polys.length;i++){
      beginShape();
      for(int j=0;j<polys[i].length;j++)
        vertex(scl*polys[i][j][0],scl*polys[i][j][1],scl*polys[i][j][2]);
      endShape(CLOSE);
    }

    stroke(lineStrokeColor);
    noFill();

    for(int i=0;i<lines.length;i++){
      beginShape();
      for(int j=0;j<lines[i].length;j++)
        vertex(scl*lines[i][j][0],scl*lines[i][j][1],scl*lines[i][j][2]);
      endShape();
    }

    popMatrix();
  }
  //---------------
  int parseInt(String s){
    return Integer.parseInt( trim(s) );
  }
  //---------------
  void loadGeometry(String filename){
    // this is nasty, poorly documented code
    // suffice to say, the data files must be writter EXACTLY to specification
    // a line break too many or a missing space is enough to crash the parser
    String[] file = loadStrings("geometry/"+filename+".txt");
    int polyCount, lineCount, offset=6;

    polyCount = parseInt( file[0].substring(9) );
    lineCount = parseInt( file[1].substring(6) );
    scl = Float.parseFloat( file[2].substring(6) );
    polys = new int[polyCount][][];
    lines = new int[lineCount][][];

    // parse polygons
    for(int i=0 ; i<polyCount ; i++){
      // parse polygon vertex count
      polys[i] = new int[ parseInt( file[offset++].substring(9) ) ][];
      for(int j=0 ; j<polys[i].length ; j++){
        // parse polygon vertex
        String[] tmp = split( file[offset] , ',' );
        polys[i][j] = new int[]{ 
          parseInt(tmp[0]), parseInt(tmp[1]), parseInt(tmp[2])
          };
          offset++;
      }
      offset++;
    }

    offset+=2;

    // parse lines
    for(int i=0 ; i<lineCount ; i++){
      // parse line vertex count
      lines[i] = new int[ parseInt( file[offset++].substring(9) ) ][];
      for(int j=0 ; j<lines[i].length ; j++){
        // parse line vertex
        String[] tmp = split( file[offset] , ',' );
        lines[i][j] = new int[]{ 
          parseInt(tmp[0]), parseInt(tmp[1]), parseInt(tmp[2])
          };
          offset++;
      }
      offset++;
    }

  }
}
//==========================
// contains all media for object references
class MediaBank{
  PImage highlightIcon, buttonMask, unavailibleButton;
  Geometry[] geometryList;
  Enemy[] enemyTemplates;
  String[] geoNameList;
  String[] enemyNameList;
  MediaBank(){
    highlightIcon = loadImage("icons/glow.gif");
    highlightIcon.mask( loadImage("icons/glowmask.gif") );
    buttonMask = loadImage("icons/buttonmask.gif");
    unavailibleButton = loadImage("icons/unavailible.gif");
    unavailibleButton.mask( loadImage("icons/unavailiblemask.gif") );
  }
  //---------------
  void loadGeometries(){
    geoNameList = loadStrings("geometry/_geolist.txt");
    geometryList = new Geometry[ geoNameList.length ];
    for(int i=0;i<geoNameList.length;i++)
      geometryList[i] = new Geometry( geoNameList[i] );
  }
  //---------------
  void loadEnemies(){
    enemyNameList = loadStrings("enemies/_enemylist.txt");
    enemyTemplates = new Enemy[ enemyNameList.length ];
    for(int i=0;i<enemyNameList.length;i++)
      enemyTemplates[i] = new Enemy( enemyNameList[i] );
  }
  //---------------
  Geometry getGeometry(String s){
    for(int i=0;i<geoNameList.length;i++)
      if( geoNameList[i].equals(s) )
        return geometryList[i];
    return null;
  }
  //---------------
  int getEnemyIndex(String s){
    for(int i=0;i<enemyNameList.length;i++)
      if( enemyNameList[i].equals(s) )
        return i;
    return 0;
  }
}