//==========================
class NextBoardButton extends Button{
  NextBoardButton(int x, int y){
    super(x,y,'!',loadImage("icons/next.gif"),game.mediabank.highlightIcon, new Description());
    sticky = true;
    showInfowindow = false;
  }
  //---------------
  void click(){
    // cancel any actions from previous map
    for(int i=0;i<game.buttons.length;i++)
      if(!game.buttons[i].sticky) game.buttons[i].deselect();
    
    game.loadBoard( game.boardNumber+1 );
    deselect();
    hide();
  }
  void boardClick(int mx, int my, float planex, float planey, int gridx, int gridy){
  }
}
//==========================
class RestartButton extends Button{
  RestartButton(int x, int y){
    super(x,y,'!',loadImage("icons/next.gif"),game.mediabank.highlightIcon, new Description());
    sticky = true;
    showInfowindow = false;
  }
  //---------------
  void click(){
    // cancel any actions from previous map
    for(int i=0;i<game.buttons.length;i++)
      if(!game.buttons[i].sticky) game.buttons[i].deselect();
    initGame();
    deselect();
  }
  void boardClick(int mx, int my, float planex, float planey, int gridx, int gridy){
  }
}
//==========================
class PauseButton extends Button{
  PauseButton(int x, int y){
    super(x,y,'p',loadImage("icons/pause.gif"),game.mediabank.highlightIcon, new Description("Play"));
    sticky = true;
  }
  //---------------
  void click(){
    selected = !selected;
    if(selected)
      game.pause();
    else
      game.unpause();
  }
  void boardClick(int mx, int my, float planex, float planey, int gridx, int gridy){
  }
}
//==========================
class SelectButton extends Button{
  SelectButton(int x, int y){
    super(x,y,'x',loadImage("icons/select.gif"),game.mediabank.highlightIcon, new Description("Examine","Reveals information about game entities"));
  }
  void boardClick(int mx, int my, float planex, float planey, int gridx, int gridy){
  }
}
//==========================
class DefenseButton extends Button{
  DefenseButton(int x, int y){
    super(x,y,'!',loadImage("icons/defense.gif"),loadImage("icons/defense_on.gif"), new Description());
    description.hide();
    sticky = true;
  }
  void click(){
    select();
    game.toolCategoryButton.deselect();
    game.researchCategoryButton.deselect();
    for(int i=0;i<game.defenseButtons.length;i++)
      game.defenseButtons[i].show();
    for(int i=0;i<game.toolButtons.length;i++)
      game.toolButtons[i].hide();
    for(int i=0;i<game.researchButtons.length;i++)
      game.researchButtons[i].hide();
  }
  void boardClick(int mx, int my, float planex, float planey, int gridx, int gridy){
  }
}
//==========================
class ToolButton extends Button{
  ToolButton(int x, int y){
    super(x,y,'!',loadImage("icons/tools.gif"),loadImage("icons/tools_on.gif"), new Description());
    description.hide();
    sticky = true;
  }
  void click(){
    select();
    game.defenseCategoryButton.deselect();
    game.researchCategoryButton.deselect();
    for(int i=0;i<game.defenseButtons.length;i++)
      game.defenseButtons[i].hide();
    for(int i=0;i<game.toolButtons.length;i++)
      game.toolButtons[i].show();
    for(int i=0;i<game.researchButtons.length;i++)
      game.researchButtons[i].hide();
  }
  void boardClick(int mx, int my, float planex, float planey, int gridx, int gridy){
  }
}
//==========================
class ResearchButton extends Button{
  ResearchButton(int x, int y){
    super(x,y,'!',loadImage("icons/research.gif"),loadImage("icons/research_on.gif"), new Description());
    description.hide();
    sticky = true;
  }
  void click(){
    select();
    game.defenseCategoryButton.deselect();
    game.toolCategoryButton.deselect();
    for(int i=0;i<game.defenseButtons.length;i++)
      game.defenseButtons[i].hide();
    for(int i=0;i<game.toolButtons.length;i++)
      game.toolButtons[i].hide();
    for(int i=0;i<game.researchButtons.length;i++)
      game.researchButtons[i].show();
  }
  void boardClick(int mx, int my, float planex, float planey, int gridx, int gridy){
  }
}
//==========================
class TransmitterButton extends Button{
  TransmitterButton(int x, int y){
    super(x,y,'1',loadImage("icons/transmitter.gif"),game.mediabank.highlightIcon, game.transmitter.getDescription() );
  }
  void click(){
    super.click();
    game.defenseCategoryButton.click();
  }
  void boardClick(int mx, int my, float planex, float planey, int gridx, int gridy){
    if( game.attemptConstruction( new Transmitter(gridx,gridy), gridx,gridy ) )
      deselect();
  }
}
//==========================
class TrinaryButton extends Button{
  TrinaryButton(int x, int y){
    super(x,y,'2',loadImage("icons/trinary.gif"),game.mediabank.highlightIcon, game.trinary.getDescription() );
  }
  void click(){
    super.click();
    game.defenseCategoryButton.click();
  }
  void boardClick(int mx, int my, float planex, float planey, int gridx, int gridy){
    if( game.attemptConstruction( new Trinary(gridx,gridy), gridx,gridy ) )
      deselect();
  }
}
//==========================
class TesseractButton extends Button{
  TesseractButton(int x, int y){
    super(x,y,'3',loadImage("icons/tesseract.gif"),game.mediabank.highlightIcon, game.tesseract.getDescription() );
  }
  void click(){
    super.click();
    game.defenseCategoryButton.click();
  }
  void boardClick(int mx, int my, float planex, float planey, int gridx, int gridy){
    if( game.attemptConstruction( new Tesseract(gridx,gridy), gridx,gridy ) )
      deselect();
  }
}
//==========================
class ConstantButton extends Button{
  ConstantButton(int x, int y){
    super(x,y,'4',loadImage("icons/constant.gif"),game.mediabank.highlightIcon, game.constant.getDescription() );
  }
  void click(){
    super.click();
    game.defenseCategoryButton.click();
  }
  void boardClick(int mx, int my, float planex, float planey, int gridx, int gridy){
    if( game.attemptConstruction( new Constant(gridx,gridy), gridx,gridy ) )
      deselect();
  }
}
//==========================
class RecycleButton extends Button{
  RecycleButton(int x, int y){
    super(x,y,'r',loadImage("icons/recycle.gif"),game.mediabank.highlightIcon, new Description("Recycle","recycles an existing structure") );
  }
  void click(){
    super.click();
    game.toolCategoryButton.click();
  }
  void boardClick(int mx, int my, float planex, float planey, int gridx, int gridy){
    Defense d = game.objs.getDefenseAtPoint(planex,planey);
    if(d!=null){
      deselect();
      game.postMessage( (d.cycleCost/2)+" cycles and "+(d.memoryCost/2)+" memory recycled");
      game.cycles += d.cycleCost/2;
      game.memory += d.memoryCost/2;
      d.kill();
    };
  }
}
//==========================
class PrioritizeButton extends Button{
  PrioritizeButton(int x, int y){
    super(x,y,'e',loadImage("icons/prioritize.gif"),game.mediabank.highlightIcon, new Description("Prioritize","mark an enemy as a priority. \n\nshortcut:\nright mouse button") );
  }
  void click(){
    super.click();
    game.toolCategoryButton.click();
  }
  void boardClick(int mx, int my, float planex, float planey, int gridx, int gridy){
    Enemy e = game.objs.getEnemyAtPoint(planex,planey);
    if(e!=null) game.objs.add( new Marker(e) );
  }
}
//==========================
class PartialFormatButton extends Button{
  int cooldown, cooldownTime;
  int cycleCost = 2, memoryCost = 0;
  PartialFormatButton(int x, int y){
    super(x,y,'f',loadImage("icons/partialformat.gif"),game.mediabank.highlightIcon, new Description("Partial Format", "completely erases everything in a 3*3 cell region") );
    description.cycleCost = 2;
    description.showPrice = true;
    description.showTechnical = true;
    cooldownTime = 250;
  }
  //---------------
  void visualize(){
    if(visible){
      image( icon, x, y);

      if( !(cooldown==0 && game.cycles>=cycleCost && game.memory>=memoryCost) )
        image( game.mediabank.unavailibleButton, x, y);

      if(selected) image( highlight, x, y );
      if( mouseX>x && mouseX<x+w && mouseY>y && mouseY<y+h && description!= null ){
        description.technical = new String[][]{ 
          new String[]{
            "recharging:",(int)(100-cooldown*100/cooldownTime)+"%"                                        } 
        };
        if(cooldown==0)
        description.technical = new String[][]{ 
          new String[]{
            "charge:","100%"                                        } 
        };
        game.drawInfowindow( description );
      }
    }
  }
  //---------------
  void update(){
    if(cooldown>0) cooldown--;
  }
  void click(){
    super.click();
    game.toolCategoryButton.click();
  }
  //---------------
  void boardClick(int mx, int my, float planex, float planey, int gridx, int gridy){
    if(cooldown==0)
      if(game.cycles >= cycleCost && game.memory >= memoryCost)
        if( game.terrain.isCellInsideMap( gridx,gridy ) ){
          game.objs.add( new PartialFormat(gridx,gridy) );
          game.cycles -= cycleCost;
          game.memory -= memoryCost;
          cooldown = cooldownTime;
          deselect();
        }
  }
}
//==========================
class UpgradeAttackButton extends Button{
  UpgradeAttackButton(int x, int y){
    super(x,y,'j',loadImage("icons/upgrade_attack.gif"),game.mediabank.highlightIcon, new Description() );
    description.heading = "Upgrade damage";
    description.about = "+20% damage";
    description.cycleCost = 20;
    description.memoryCost = 20;
    description.showPrice = true;
    description.showAbout = true;
  }
  void click(){
    super.click();
    game.researchCategoryButton.click();
  }
  void boardClick(int mx, int my, float planex, float planey, int gridx, int gridy){
    if(game.terrain.isCellInsideMap(gridx,gridy))
      if( game.terrain.groundEntity[gridx][gridy] != null )
        if( game.terrain.groundEntity[gridx][gridy].isDefense )
          if( ((Defense)game.terrain.groundEntity[gridx][gridy]).attemptUpgradeAttack() )
            game.objs.add( new UpgradeFlash(planex,planey) );
          else
            game.postMessage("upgrade is not possible");
        else
          game.postMessage("upgrade failure at designated coordinates");
      else
        game.postMessage("upgrade failure at designated coordinates");
  }
}
//==========================
class UpgradeRangeButton extends Button{
  UpgradeRangeButton(int x, int y){
    super(x,y,'k',loadImage("icons/upgrade_range.gif"),game.mediabank.highlightIcon, new Description() );
    description.heading = "Upgrade \nrange/cover";
    description.about = "";
    description.cycleCost = 20;
    description.memoryCost = 20;
    description.showPrice = true;
    description.showAbout = true;
  }
  void click(){
    super.click();
    game.researchCategoryButton.click();
  }
  void boardClick(int mx, int my, float planex, float planey, int gridx, int gridy){
    if(game.terrain.isCellInsideMap(gridx,gridy))
      if( game.terrain.groundEntity[gridx][gridy] != null )
        if( game.terrain.groundEntity[gridx][gridy].isDefense )
          if( ((Defense)game.terrain.groundEntity[gridx][gridy]).attemptUpgradeRange() )
            game.objs.add( new UpgradeFlash(planex,planey) );
          else
            game.postMessage("upgrade is not possible");
        else
          game.postMessage("upgrade failure at designated coordinates");
      else
        game.postMessage("upgrade failure at designated coordinates");
  }
}
//==========================
class UpgradeFirerateButton extends Button{
  UpgradeFirerateButton(int x, int y){
    super(x,y,'l',loadImage("icons/upgrade_firerate.gif"),game.mediabank.highlightIcon, new Description() );
    description.heading = "Upgrade \nrate of fire";
    description.about = "-20% cool down";
    description.cycleCost = 20;
    description.memoryCost = 20;
    description.showPrice = true;
    description.showAbout = true;
  }
  void click(){
    super.click();
    game.researchCategoryButton.click();
  }
  void boardClick(int mx, int my, float planex, float planey, int gridx, int gridy){
    if(game.terrain.isCellInsideMap(gridx,gridy))
      if( game.terrain.groundEntity[gridx][gridy] != null )
        if( game.terrain.groundEntity[gridx][gridy].isDefense )
          if( ((Defense)game.terrain.groundEntity[gridx][gridy]).attemptUpgradeFirerate() )
            game.objs.add( new UpgradeFlash(planex,planey) );
          else
            game.postMessage("upgrade is not possible");
        else
          game.postMessage("upgrade failure at designated coordinates");
      else
        game.postMessage("upgrade failure at designated coordinates");
  }
}
//==========================
class Button{
  PImage icon;
  PImage highlight;
  int x,y,w,h,radius;
  boolean visible, selected, sticky, showInfowindow;
  char hotkey;
  Description description;
  Button(int x, int y, char hotkey, PImage icon, PImage highlight, Description description){
    this.highlight = highlight;
    this.description = description;
    description.hotkey = hotkey;
    this.x = x;
    this.y = y;
    this.hotkey = hotkey;
    this.icon = icon;
    w = icon.width;
    h = icon.height;
    if(w==16 && h==16) this.icon.mask(game.mediabank.buttonMask);
    radius = icon.width/2;
    visible = true;
    showInfowindow = true;
  }
  //---------------
  void update(){
  }
  //---------------
  void visualize(){
    if(visible){
      image( icon, x, y);
      if(selected) image( highlight, x, y );
      if( mouseX>x && mouseX<x+w && mouseY>y && mouseY<y+h && description!= null )
        if(showInfowindow)
          game.drawInfowindow( description );
    }
  }
  //---------------
  void select(){
    selected = true;
  }
  //---------------
  void deselect(){
    selected = false;
  }
  //---------------
  void show(){
    visible = true;
  }
  //---------------
  void hide(){
    visible = false;
  }
  //---------------
  void mouseInput(int mx, int my){
    if( !(mx>x && mx<x+w && my>y && my<y+h) ){
      if(selected){
        float[] planePoint = game.screenToPlaneCoords(mx,my);
        int gx = game.terrain.xGrid( planePoint[0] );
        int gy = game.terrain.yGrid( planePoint[1] );
        boardClick(mouseX,mouseY,planePoint[0],planePoint[1],gx,gy);
      }
    }
    else
      if(visible) click();
  }
  //---------------
  void keyInput(char key){
    if(key==hotkey && hotkey!='!') click();
  }
  //---------------
  void click(){
    for(int i=0;i<game.buttons.length;i++)
      if(game.buttons[i]!=this && !game.buttons[i].sticky)
        game.buttons[i].deselect();
    selected = !selected;
  }
  //---------------
  void boardClick(int mx, int my, float planex, float planey, int gridx, int gridy){
    selected = false;
  }
}
//==========================
// an object containing an description
class Description{
  String heading, about;
  char hotkey;
  String[][] technical;
  int cycleValue, memoryValue, cycleCost, memoryCost;
  boolean showAbout, showTechnical, showPrice, visible;
  Description(){
    heading = "";
    about = "";
    technical = new String[0][0];
    hotkey = '!';
    cycleValue= memoryValue= cycleCost= memoryCost = 0;
    showAbout = showTechnical = showPrice = false;
    visible = true;
  }
  Description(String a){
    this();
    heading = a;
  }
  Description(String a,String b){
    this();
    heading = a;
    about = b;
    showAbout = true;
  }
  void hide(){
    visible = false;
  }
}