//==========================
class Menu{
  Tile[][] tiles;
  int startGameTimer = 0;
  int animationLength = 75;
  boolean startGame;
  Menu(){
    PImage logo = loadImage("logo.gif");
    int tileSize = 600/logo.width;
    tiles = new Tile[ (width/tileSize) ][ (height/tileSize) ];

    for(int x=0;x<tiles.length;x++)
      for(int y=0;y<tiles[0].length;y++)
        tiles[x][y] = new Tile( tileSize/2 + x*tileSize, tileSize/2 + y*tileSize, tileSize/2, logo.pixels[x+y*logo.width] == color(0) );
  }
  //---------
  void radialZoom(){
    int start = (startGameTimer-7);
    int stop = (startGameTimer-5);
    if(startGame)
      for(int x=0;x<tiles.length;x++)
        for(int y=0;y<tiles[0].length;y++){
          float d = dist(x,y,tiles.length/2,tiles[0].length/2);
          if( start < d && stop > d ){
            tiles[x][y].flip( 100 );
            tiles[x][y].uninvert();
          }
        }
  }
  //---------
  void noiseReveal(){
    int start = (startGameTimer-13);
    int stop = (startGameTimer-10);
    if(startGame)
      for(int x=0;x<tiles.length;x++)
        for(int y=0;y<tiles[0].length;y++){
          if( start < tiles[x][y].noiseValue && stop > tiles[x][y].noiseValue ){
            tiles[x][y].flip( 50 );
            tiles[x][y].uninvert();
          }
        }
  }
  //---------
  void visualize(){

    lights();

    if(startGame) noiseReveal();

    if(startGameTimer > 0) startGameTimer--;

    if(startGame && startGameTimer==0) startGame();

    background(0);
    if(startGame)
      for(int x=0;x<tiles.length;x++)
        for(int y=0;y<tiles[0].length;y++)
          tiles[x][y].visualize(-100,-100); // remove mouse-"pointer" from canvas if startGame

    if(!startGame)
      for(int x=0;x<tiles.length;x++)
        for(int y=0;y<tiles[0].length;y++)
          tiles[x][y].visualize(mouseX,mouseY);

    textMode(SCREEN);
    fill(0);
    textAlign(RIGHT);
    text("version Beta.9.0",width-19,25);
    text("made by skanaar",width-17,45);
  }
  //---------
  void mouseReleased( float mouseX, float mouseY ){
    if(!startGame){
      startGame = true;
      startGameTimer = animationLength;
      initGame();
    }
  }
  //---------
  void keyReleased( char k, int kc ){
    if(k=='x'){
      initGame();
      startGame();
    }
  }
  //==========================
  class Tile{
    int x, y;
    float value, radius, range, openSpeed, closeSpeed, noiseValue;
    color col;
    boolean inverted;
    Tile(int x, int y, float radius, boolean inverted){
      this.x = x;
      this.y = y;
      noiseValue = animationLength*noise(x*0.01,y*0.01);
      this.radius = radius;
      this.inverted = inverted;
      col = color(64,128,255);
      range = 3*radius;
      openSpeed = 32;
      closeSpeed = 16;
      if(inverted) closeSpeed = random(2,8);
      if(inverted) value = 100;
    }
    //---------
    void uninvert(){
      if(inverted) value = 100-value;
      inverted = false;
      closeSpeed = 16;
    }
    //---------
    void flip(float a){
      value = constrain( value+a , 0 , 100 );
    }
    //---------
    void visualize(int mx, int my){

      float d = dist(mx,my,x,y);

      if( d<range )
        value = constrain( value+ max(0,openSpeed*(range-d)/range) , 0 , 100 );
      else
        value = constrain( value-closeSpeed , 0 , 100 );

      noStroke();
      fill(col);

      float boxSize = value*(radius*2-1)/100f;
      if(inverted) boxSize = radius*2-boxSize-1;

      pushMatrix();
      translate(x,y,0);
      if(boxSize>1) box(boxSize);
      popMatrix();
    }
  }
}