//==========================
class Missile extends Entity{
  float tx,ty,tz;
  int damage, splash;
  float vx,vy,vz, speed = 6f;
  float[][] trail;
  Missile(float x, float y, float z, Enemy target, int damage, int splash){
    this.x = x;
    this.y = y;
    this.z = z;
    tx = target.x;
    ty = target.y;
    tz = target.z;

    vx = tx-x;
    vy = ty-y;
    vz = tz-z;
    float factor = speed/mag(vx,vy,vz);
    vx *= factor;
    vy *= factor;
    vz *= factor;

    this.damage = damage;
    this.splash = splash;
    trail = new float[5][3];
    for(int i=0;i<trail.length;i++)
    trail[i] = new float[]{
      x,y,z        };
  }
  //---------------
  void update(){
    x += vx;
    y += vy;
    z += vz;

    if(z<-2) kill();

    // update trail
    for(int i=0;i<trail.length-1;i++)
      trail[i] = trail[i+1];
    trail[trail.length-1] = new float[]{
      x,y,z        };
  }
  //---------------
  void kill(){
    game.objs.add( new Atomic(x,y,z+5) );
    // deliver damage
    for(int i=0;i<game.objs.objs.size();i++)
      if( game.objs.get(i).isEnemy ){
        Enemy e = (Enemy) game.objs.get(i);
        float d = mag(e.x-x,e.y-y,e.z-z);
        if( d < splash )
          e.inflictDamage( (int)( damage*d/splash ) );
      }
    super.kill();
  }
  //---------------
  void visualize(){
    noStroke();
    for(int i=0;i<trail.length;i++){
      pushMatrix();
      translate(trail[i][0],trail[i][1],trail[i][2]);
      fill(255,i*255f/trail.length+16);
      box(3*(i/(float)trail.length));
      fill(255,0,0,i*128f/trail.length+16);
      box(2+3*(i/(float)trail.length));
      popMatrix();
    }
  }
  //---------------
  Enemy getEnemy(){
    // first get the prioritized enemies
    for(int i=0;i<game.objs.objs.size();i++)
      if( game.objs.get(i).isMarker )
        return (Enemy) ((Marker) game.objs.get(i)).target;

    // secondly get any enemy within range
    for(int i=0;i<game.objs.objs.size();i++)
      if( game.objs.get(i).isEnemy )
        return (Enemy) game.objs.get(i);
    return null;
  }
}
//==========================
class Seeker extends Entity{
  Enemy target;
  int damage, splash;
  float vx,vy,vz;
  float[][] trail;
  float friction = 0.96f, gravity=0.3;
  Seeker(float x, float y, float z, Enemy target, int damage, int splash){
    isDamageable = true;
    this.x = x;
    this.y = y;
    this.z = z;
    this.target = target;
    this.damage = damage;
    this.splash = splash;
    vz = 5f;
    trail = new float[5][3];
    for(int i=0;i<trail.length;i++)
    trail[i] = new float[]{
      x,y,z        };
  }
  //---------------
  void update(){
    // if the target has died, select a new target
    if(target.killMe) target = getEnemy();
    if(target==null){
      kill();
      return;
    }

    float d = dist(target.x,target.y,target.z,x,y,z);
    float friction = constrain( this.friction*d/20, 0.9, this.friction);
    vx = friction*vx + gravity*(target.x-x)/d;
    vy = friction*vy + gravity*(target.y-y)/d;
    vz = constrain( this.friction*z/25, 0.75, this.friction)*vz + gravity*(target.z-z)/d;

    x += vx;
    y += vy;
    z += vz;

    // update trail
    for(int i=0;i<trail.length-1;i++)
      trail[i] = trail[i+1];
    trail[trail.length-1] = new float[]{
      x,y,z        };

    if(d<7)
      kill();
  }
  //---------------
  void kill(){
    game.objs.add( new Cubeplosion(x,y,z) );
    // deliver damage
    for(int i=0;i<game.objs.objs.size();i++)
      if( game.objs.get(i).isEnemy ){
        Entity e = game.objs.get(i);
        float d = max(0,-7+mag(e.x-x,e.y-y,e.z-z));
        if( d < splash )
          e.inflictDamage( (int)( damage*(splash-d)/splash ) );
      }
    super.kill();
  }
  //---------------
  void visualize(){
    noStroke();
    for(int i=0;i<trail.length;i++){
      pushMatrix();
      translate(trail[i][0],trail[i][1],trail[i][2]);
      fill(255,i*255f/trail.length+16);
      box(1);
      fill(255,i*128f/trail.length+16);
      box(3);
      popMatrix();
    }
  }
  //---------------
  Enemy getEnemy(){
    // first get the prioritized enemies
    for(int i=0;i<game.objs.objs.size();i++)
      if( game.objs.get(i).isMarker ){
        Marker mark = (Marker) game.objs.get(i);
        return (Enemy) mark.target;
      }

    // secondly get any enemy within range
    for(int i=0;i<game.objs.objs.size();i++)
      if( game.objs.get(i).isEnemy )
        return (Enemy) game.objs.get(i);
    return null;
  }
}
//==========================
class SiphonTentacle extends Entity{
  Enemy target;
  int damage, slow;
  float vx,vy,vz;
  float dx,dy,dz;
  float[][] trail;
  float friction = 0.96f, gravity=0.3;
  SiphonTentacle(float x, float y, float z, Enemy target, int damage, int slow){
    this.x = x;
    this.y = y;
    this.z = z;
    this.target = target;
    this.damage = damage;
    this.slow = slow;
    vz = 5f;
    dx = random(-2,2);
    dy = random(-2,2);
    dz = random(-2,2);
    trail = new float[5][3];
    for(int i=0;i<trail.length;i++)
    trail[i] = new float[]{
      x,y,z        };
  }
  //---------------
  void update(){
    // if the target has died, select a new target
    if(target.killMe) target = getEnemy();
    if(target==null){
      kill();
      return;
    }

    float d = dist(target.x,target.y,target.z,x,y,z);
    float friction = constrain( this.friction*d/20, 0.9, this.friction);
    vx = friction*vx + gravity*(target.x-x)/d;
    vy = friction*vy + gravity*(target.y-y)/d;
    vz = constrain( this.friction*z/25, 0.75, this.friction)*vz + gravity*(target.z-z)/d;

    x += vx;
    y += vy;
    z += vz;

    // update trail
    for(int i=0;i<trail.length-1;i++)
      trail[i] = trail[i+1];
    trail[trail.length-1] = new float[]{
      x,y,z        };

    if(d<7)
      kill();
  }
  //---------------
  void kill(){
    game.objs.add( new Cubeplosion(x,y,z) );
    // deliver damage
    for(int i=0;i<game.objs.objs.size();i++)
      if( game.objs.get(i).isEnemy ){
        Enemy e = (Enemy) game.objs.get(i);
        e.inflictDamage(damage);
      }
    super.kill();
  }
  //---------------
  void visualize(){
    noStroke();
    for(int i=0;i<trail.length;i++){
      pushMatrix();
      translate(trail[i][0],trail[i][1],trail[i][2]);
      fill(255,i*255f/trail.length+16);
      box(1);
      fill(255,i*128f/trail.length+16);
      box(3);
      popMatrix();
    }
  }
  //---------------
  Enemy getEnemy(){
    // first get the prioritized enemies
    for(int i=0;i<game.objs.objs.size();i++)
      if( game.objs.get(i).isMarker ){
        Marker mark = (Marker) game.objs.get(i);
        return (Enemy) mark.target;
      }

    // secondly get any enemy within range
    for(int i=0;i<game.objs.objs.size();i++)
      if( game.objs.get(i).isEnemy )
        return (Enemy) game.objs.get(i);
    return null;
  }
}
//==========================
class CPU extends Entity{
  int w, steps, stepH, gridX, gridY, timer;
  CPU(float x, float y, int gridX, int gridY){
    this.x = x;
    this.y = y;
    this.gridX = gridX;
    this.gridY = gridY;
    this.w = 8;
    stepH = 4;
    steps = (int) random(1,4);
    game.cpus += steps;
    isCPU = true;
    timer = 0;
  }
  //---------------
  void inflictDamage(int dam){
    game.cpus -= min( steps, dam);
    steps -= min( steps, dam);
    if(steps<=0)
      kill();
  }
  //---------------
  void kill(){
    game.cpus -= max( steps, 0);
    super.kill();
    game.terrain.isCPU[gridX][gridY] = false;
    game.terrain.groundEntity[gridX][gridY] = null;
  }
  //---------------
  void update(){
    timer = (timer+1) % (steps*20+20);
  }
  //---------------
  void visualize(){

    for(int i=0;i<steps*2;i++){
      fill(255,255,0,64);
      stroke(255,255,128,86);
      if(i==(timer/20)){
        fill(255,255,192,128);
        stroke(255,255,192,86);
      }

      beginShape();
      vertex(x-w,y-w,1+stepH*(i));
      vertex(x-w,y+w,1+stepH*(i));
      vertex(x+w,y+w,1+stepH*(i));
      vertex(x+w,y-w,1+stepH*(i));
      endShape(CLOSE);
    }
  }
}
//==========================
class PartialFormat extends Entity{
  PartialFormat(int gridx, int gridy){
    for(int i=0;i<game.objs.objs.size();i++)
      for(int x=-1;x<2;x++)
        for(int y=-1;y<2;y++){
          int entGridX = game.terrain.xGrid(game.objs.get(i).x);
          int entGridY = game.terrain.yGrid(game.objs.get(i).y);
          if( entGridX==gridx+x && entGridY==gridy+y && !game.objs.get(i).isInvulnerable )
            game.objs.get(i).kill();
        }
    for(int x=-1;x<2;x++)
      for(int y=-1;y<2;y++){
        game.terrain.groundEntity[gridx+x][gridy+y] = null;
        game.terrain.isPath[gridx+x][gridy+y] = true;
        game.objs.add( new Deletion(gridx+x,gridy+y) );
      }
    game.terrain.calculateAIPath();
  }
  //---------------
  void update(){
    kill();
  }
  //---------------
  void visualize(){
  }
}
//==========================
class PartialFormatRangeDrawer extends Entity{
  void drawRange(float x, float y){
    float x2 = game.terrain.xPos( game.terrain.xGrid(x) ) - game.terrain.cellSize*1.5;
    float y2 = game.terrain.yPos( game.terrain.yGrid(y) ) - game.terrain.cellSize*1.5;
    fill(255,0,0,32);
    stroke(255,0,0,128);
    pushMatrix();
    translate( x2,y2, 2 );
    rect(0,0,3*game.terrain.cellSize,3*game.terrain.cellSize);
    popMatrix();
  }
}
//==========================
class Marker extends Entity{
  Entity target;
  Marker(Entity target){
    this.target = target;
    isMarker = true;
  }
  //---------------
  void update(){
    x = target.x;
    y = target.y;
    z = target.z;
    if( target.killMe ) kill();
  }
  //---------------
  void visualize(){
    stroke(255);
    fill(255,128);
    pushMatrix();
    translate(x,y,10);

    beginShape(TRIANGLE_FAN);
    vertex(0,0,0);
    vertex( 6, 6,20);
    vertex(-6, 6,20);
    vertex(-6,-6,20);
    vertex( 6,-6,20);
    vertex( 6, 6,20);
    endShape();

    popMatrix();
  }
}
//==========================
class Spawnpoint extends Entity{
  int gridx, gridy, timer, frequency, amount, delay, index;
  float[][] sparks;
  float radius, cubeside;
  float[] probabilities;
  int[] spawnList;
  boolean isVisible;
  //---------------
  // INPUT: enemylist: array where enemyList[i] is the number of {enemy type i}
  Spawnpoint(int tx, int ty, int frequency, int delay, int[] enemyList, boolean isVisible){
    gridx = tx;
    gridy = ty;
    x = game.terrain.xPos(gridx);
    y = game.terrain.yPos(gridy);
    z = 11;
    radius = 10;
    cubeside = 20;
    this.frequency = frequency;
    this.delay = delay;
    this.isVisible = isVisible;
    isInvulnerable = true;
    isSpawnpoint = true;

    // count the number of enemies
    amount = 0;
    for(int i=0;i<enemyList.length;i++)
      amount += enemyList[i];
    // fill the spawnlist with amount dictated in enemylist
    spawnList = new int[ amount ];
    int counter=0;
    for(int i=0;i<enemyList.length;i++)
      for(int j=0;j<enemyList[i];j++){
        spawnList[counter] = i;
        counter++;
      }
    // randomize the spawnlist
    for(int i=0;i<spawnList.length;i++){
      int index = (int) random(0,spawnList.length);
      int temp = spawnList[i];
      spawnList[i] = spawnList[index];
      spawnList[index] = temp;
    }

    sparks = new float[50][3];
    for(int i=0;i<sparks.length;i++){
      sparks[i] = new float[]{ 
        random(-1,1),random(-1,1),random(-1,1)                         };
      float d = mag(sparks[i][0],sparks[i][1],sparks[i][2]);
      sparks[i][0] *= radius/d; 
      sparks[i][1] *= radius/d; 
      sparks[i][2] *= radius/d; 
    }
  }
  //---------------
  void update(){
    timer++;
    if( timer>delay && ((timer-delay) % frequency)==0 && amount>0 ) spawnEnemies();
  }
  //---------------
  void visualize(){
    stroke(255, 64);
    noFill();
    if(isVisible)
      for(int i=0;i<constrain(timer*8f/delay,0,8);i++){
        pushMatrix();
        translate(x,y,z);
        rotateY(i*PI*0.06);
        rotateZ( timer*HALF_PI*0.025);
        box( cubeside-2*i );
        popMatrix();
      }
  }
  //---------------
  void visualizeWormhole(){
    stroke(255, 128);
    noFill();
    pushMatrix();
    translate(x,y,z);
    rotateX(timer*PI/frequency);
    rotateZ(timer*HALF_PI/frequency);

    for(int i=0;i<sparks.length;i++)
      point( sparks[i][0],sparks[i][1],sparks[i][2] );

    float f = 1 + (timer%40)*0.25;
    for(int i=0;i<sparks.length;i++){
      stroke(255, random(128) );
      line( sparks[i][0],sparks[i][1],sparks[i][2], f*sparks[i][0],f*sparks[i][1],f*sparks[i][2] );
    }
    popMatrix();
  }
  //---------------
  void spawnEnemies(){
    int spawn = spawnList[amount-1];
    //String type = game.mediabank.enemyNameList[spawn];
    game.objs.add( new Enemy( spawn,gridx,gridy ) );
    amount--;
  }
}