class Shader{
  String name;
  float scale = 1;
  color diffuseColor;
  
  boolean useTexture;
  PImage texture;
  int imgWidth;
  
  float glowAmount;
  boolean useGlowMask;
  String glowMaskName;
  Shader glowMask;
  boolean useGlowColor;
  color glowColor;
  //-----------
  Shader(){
    name = "null";
    useTexture = false;
    useGlowMask = false;
    useGlowColor = false;
    glowAmount = 0;
    glowColor = color(255);
  }
  //-----------
  void setTexture(String file){
    useTexture = true;
    texture = loadImage("textures/"+file);
    imgWidth = texture.width;
  }
  //-----------
  void setGlowMaskName(String file){
    useGlowMask = true;
    glowMaskName = file;
  }
  //-----------
  void setGlowColor(color c){
    useGlowColor = true;
    glowColor = c;
  }
  //-----------
  void parse(String[] strs, int s){
    for(  ; s<strs.length ; s++ ){
      String[] ex = trim(strs[s]).split(" *: *| *, *");
      
      if( ex[0].equals("name") )      name = ex[1];
      if( ex[0].equals("scale") )     scale = Float.parseFloat( ex[1] );
      if( ex[0].equals("color") )     diffuseColor = color( int(ex[1]) , int(ex[2]) , int(ex[3]) );
      if( ex[0].equals("glow") )      glowAmount = Float.parseFloat( ex[1] );
      if( ex[0].equals("glowColor") ) setGlowColor( color(int(ex[1]),int(ex[2]),int(ex[3])) );
      if( ex[0].equals("glowMask") )  setGlowMaskName( ex[1] );
      if( ex[0].equals("texture") )   setTexture(ex[1]);
      
      if( trim(strs[s]).equals("}") ) break;
    }
  }
  //-----------
  void resolveDependencies(){
    for( int i=0 ; i<shaders.length ; i++ )
      if( shaders[i].name.equals( glowMaskName ) ){
        glowMask = shaders[i];
        break;
      }
  }
  //-----------
  color getColor( Vector3D pos, Vector3D normal, Vector3D light ){
    int u,v;
    color baseColor, shadedColor, finalColor;
    float shade = normal.cosine(light);
    shade = ( shade>0 ? shade : 0 );
    
    if( useTexture ){
      u = (int)( pos.x/scale + imgWidth/2  );
      v = (int)( pos.z/scale + imgWidth/2 );
      baseColor = texture.get(u,v);
    }
    else{
      baseColor = diffuseColor;
    }
    
    shadedColor = lerpColor( color(0,255), baseColor, shade );
    
    glowColor = ( useGlowColor ? glowColor : baseColor );
    float glow = ( useGlowMask ? brightness(glowMask.getColor(pos,normal,light))/255f : 1 );
    finalColor = lerpColor( shadedColor, glowColor, glowAmount*glow );
      
    return finalColor;
  }
}