class Solid{
  float atomSize;
  float detail;
  int renderingIterations;
  int renderingLimit;
  int iterations;
  boolean finished;
  Transform transform;
  Shader shader;
  //-----------
  Solid(){
    atomSize = 2;
    finished = false;
    detail = 0.1;
    renderingLimit = 1000000;
    renderingIterations = 1000;
    iterations = 0;
    transform = new Transform();
    setShader( shaders[0] );
  }
  //-----------
  void setShader(Shader s){
    shader = s;
  }
  //-----------
  void parse(String[] strs, int s){}
  //--------------------
  void fillNumericArguments(String expression,float[] arguments){
    String[] args = trim(expression).split(",");
    for( int i=0 ; i<args.length ; i++ )
      arguments[i] = float( args[i] );
  }
  //-----------
  void universalPropertiesParse(String expression){
    String[] ex = trim(expression).split(" *: *| *, *");
    if( ex[0].equals("atomSize") ) atomSize = Float.parseFloat( ex[1] );
    if( ex[0].equals("detail") ) detail = Float.parseFloat( ex[1] );
    if( ex[0].equals("renderingIterations") ) renderingIterations = Integer.parseInt( ex[1] );
    if( ex[0].equals("renderingLimit") ) renderingLimit = Integer.parseInt( ex[1] );
    if( ex[0].equals("atomSize") ) atomSize = Float.parseFloat( ex[1] );
    if( ex[0].equals("scale") ) transform.scale( Float.parseFloat( ex[1] ) );
    if( ex[0].equals("translate") )
      transform.translate( float(ex[1]), float(ex[2]), float(ex[3]) );
    if( ex[0].equals("rotate") )
      transform.rotate( float(ex[1]), float(ex[2]), float(ex[3]) );
    if( ex[0].equals("shader") ){
      for( int i=0 ; i<shaders.length ; i++ )
        if( shaders[i].name.equals( ex[1] ) ){
          setShader( shaders[i] );
          break;
        }
    }
  }
  //-----------
  void render(
    Transform worldTransform, 
    int mode, 
    float[][] zBuffer, 
    Vector3D[][] normalBuffer, 
    Vector3D[][] localCoordBuffer, 
    Shader[][] shaderBuffer){
      
    Vector3D A = new Vector3D(0,0,atomSize);
    Vector3D B = new Vector3D(0,0,0);
    A.apply( transform );
    A.apply( worldTransform );
    B.apply( transform );
    B.apply( worldTransform );
    float atomRadius = mag(A.x-B.x, A.y-B.y, A.z-B.z);
    Atom atom = new Atom( atomRadius );
    
    float rx,ry,rz,r2x,r2y,r2z;
    for(int i=0 ; i<renderingIterations ; i++){
      iterations++;
      if( renderingLimit <= iterations ) finished = true;
      if(finished) break;
      atom.pos = ( mode==STOCHASTIC ? getRandomPosition() : getSequentialPosition() );
      atom.pos.apply( transform );
      atom.pos.apply( worldTransform );
      atom.bufferImprint( zBuffer, normalBuffer, shaderBuffer, shader);
    }
  }
  //-----------
  Vector3D getRandomPosition(){
    return new Vector3D(0,0,0);
  }
  //-----------
  Vector3D getSequentialPosition(){
    return new Vector3D(0,0,0);
  }
}
//==========================================================
//==========================================================
class Atom{
  float radius;
  Vector3D pos;
  //-----------
  Atom(float r){
    this.radius = r;
  }
  //-----------
  void bufferImprint(float[][] zBuffer, Vector3D[][] normalBuffer, Shader[][] shaderBuffer, Shader shader){
    for(int i=(int)(pos.x-radius) ; i<(int)(1+pos.x+radius) ; i++ )
      for(int j=(int)(pos.y-radius) ; j<(int)(1+pos.y+radius) ; j++ ){
        if(i<0 || i>=width || j<0 || j>=height ) continue;
        float zIntersect = sphereIntersect(i, j);
        if( zBuffer[i][j] < zIntersect ){
          zBuffer[i][j] = max( zBuffer[i][j], zIntersect );
          normalBuffer[i][j] = new Vector3D(i-pos.x,j-pos.y,zIntersect-pos.z);
          shaderBuffer[i][j] = shader;
          localCoordBuffer[i][j] = pos;
        }
      }
  }
  //-----------
  float sphereIntersect(float i, float j){
    float zSquared = radius*radius - (i-pos.x)*(i-pos.x) - (j-pos.y)*(j-pos.y);
    if(zSquared<0) return minZBuffer;
    float zIntersect = sqrt(zSquared);
    return zIntersect+pos.z;
  }
}
//==========================================================
//==========================================================