class Tube extends Solid{
  float[][][] bezierSegments;
  float t=0;
  //-----------
  Tube(){
    super();
  }
  //-----------
  void parse(String[] strs, int s){
    Vector vector = new Vector();
    
    for(  ; s<strs.length ; s++ ){
      universalPropertiesParse(strs[s]);
      // Bezier
      if( trim(strs[s]).equals("bezier") ){
        float[][] coords = new float[4][3];
        fillNumericArguments( strs[s+1], coords[0] );
        fillNumericArguments( strs[s+2], coords[1] );
        fillNumericArguments( strs[s+3], coords[2] );
        fillNumericArguments( strs[s+4], coords[3] );
        vector.add( coords );
      }
      // Line
      if( trim(strs[s]).equals("line") ){
        float[][] coords = new float[4][3];
        fillNumericArguments( strs[s+1], coords[0] );
        fillNumericArguments( strs[s+2], coords[3] );
        
        coords[1][0] = coords[0][0] + (coords[3][0] - coords[0][0]) / 3;
        coords[1][1] = coords[0][1] + (coords[3][1] - coords[0][1]) / 3;
        coords[1][2] = coords[0][2] + (coords[3][2] - coords[0][2]) / 3;
        coords[2][0] = coords[0][0] + (coords[3][0] - coords[0][0])*2 / 3;
        coords[2][1] = coords[0][1] + (coords[3][1] - coords[0][1])*2 / 3;
        coords[2][2] = coords[0][2] + (coords[3][2] - coords[0][2])*2 / 3;
        vector.add( coords );
      }
      
      if( trim(strs[s]).equals("}") ) break;
    }
    
    bezierSegments = new float[vector.size()][4][2];
    for(int i=0 ; i<vector.size() ; i++)
      bezierSegments[i] = (float[][]) (vector.elementAt(i) );
  }
  //-----------
  Vector3D getRandomPosition(){
    float x,y,z,parameter;
    t = random(0,bezierSegments.length);
    float[][] b = bezierSegments[ (int)t ];
    parameter = t%1;
    x = bezierPoint(b[0][0], b[1][0], b[2][0], b[3][0], parameter);
    y = bezierPoint(b[0][1], b[1][1], b[2][1], b[3][1], parameter);
    z = bezierPoint(b[0][2], b[1][2], b[2][2], b[3][2], parameter);
    return new Vector3D( x, y, z );
  }
  //-----------
  Vector3D getSequentialPosition(){
    float x,y,z,parameter;
    float[][] b = bezierSegments[ (int)t ];
    t += 0.01;
    if(t>=bezierSegments.length) t = random(0,0.1);
    parameter = t%1;
    x = bezierPoint(b[0][0], b[1][0], b[2][0], b[3][0], parameter);
    y = bezierPoint(b[0][1], b[1][1], b[2][1], b[3][1], parameter);
    z = bezierPoint(b[0][2], b[1][2], b[2][2], b[3][2], parameter);
    return new Vector3D( x, y, z );
  }
}