float[][] zBuffer;
Vector3D[][] normalBuffer;
Vector3D[][] localCoordBuffer;
Shader[][] shaderBuffer;
Shader[] shaders;
Solid models[];
int minZBuffer = -1024;
int w=100,h=100;
Vector3D light;
Transform worldTransform;
final int STOCHASTIC = 0;
final int SEQUENTIAL = 1;
//--------------------
void setup(){
  worldTransform = new Transform();
  light = new Vector3D(0,0,1);
  loadScene("dumbell.tdb");
  size(w,h);
  // always center the scene
  worldTransform.translate(width/2,height/2,0);
  initBuffers();
  noiseSeed( 19 );
}
//--------------------
void initBuffers(){
  shaderBuffer = new Shader[width][height];
  zBuffer = new float[width][height];
  normalBuffer = new Vector3D[width][height];
  localCoordBuffer = new Vector3D[width][height];
  for(int i=0 ; i<width ; i++)
    for(int j=0 ; j<width ; j++)
      zBuffer[i][j] = minZBuffer;
}
//-----------
void loadShaders(String file){
  Vector vector = new Vector();

  String[] strs = loadStrings(file);
  for( int i=0 ; i<strs.length ; i++ ){
    if( strs[i].matches("shader.*") ){
      Shader s = new Shader();
      s.parse( strs, i+1 );
      vector.add( s );
    }
  }

  shaders = new Shader[vector.size()];
  for(int i=0 ; i<vector.size() ; i++)
    shaders[i] = (Shader) (vector.elementAt(i) );
  for(int i=0 ; i<shaders.length ; i++)
    shaders[i].resolveDependencies();
}
//-----------
void loadScene(String file){
  loadShaders(file);

  Vector vector = new Vector();

  String[] strs = loadStrings(file);
  for( int i=0 ; i<strs.length ; i++ ){

    String row = trim(strs[i]);

    // Scene parser
    if( row.matches("scene.*") ){
      for( ; i<strs.length ; i++ ){
        String[] ex = trim(strs[i]).split(" *: *| *, *");
        if( ex[0].equals("imgSize") ){
          w = int(ex[1]);
          h = int(ex[2]);
        }
        if( ex[0].equals("scale") ) worldTransform.scale( Float.parseFloat( ex[1] ) );
        if( ex[0].equals("translate") )
          worldTransform.translate( float(ex[1]), float(ex[2]), float(ex[3]) );
        if( ex[0].equals("rotate") )
          worldTransform.rotate( float(ex[1]), float(ex[2]), float(ex[3]) );
        if( ex[0].equals("light") )
          light = new Vector3D( float(ex[1]), float(ex[2]), float(ex[3]) );
          
        if( trim(strs[i]).equals("}") ) break;
      }
    }
    // Sphere parser
    if( row.matches("sphere.*") ){
      Sphere sphere = new Sphere();
      sphere.parse( strs, i );
      vector.add( sphere );
    }
    // Tube parser
    if( row.matches("tube.*") ){
      Tube tube = new Tube();
      tube.parse( strs, i );
      vector.add( tube );
    }

    // Lathe parser
    if( row.matches("lathe.*") ){
      Lathe lathe = new Lathe();
      lathe.parse( strs, i );
      vector.add( lathe );
    }

    // Blob parser
    if( row.matches("blob.*") ){
      Blob blob = new Blob();
      blob.parse( strs, i );
      vector.add( blob );
    }

    // Hill parser
    if( row.matches("hill.*") ){
      Hill hill = new Hill();
      hill.parse( strs, i );
      vector.add( hill );
    }

  }

  models = new Solid[vector.size()];
  for(int i=0 ; i<vector.size() ; i++)
    models[i] = (Solid) (vector.elementAt(i) );
}
//--------------------
void draw(){

  loadPixels();

  for(int m=0 ; m<models.length ; m++){
    //STOCHASTIC SEQUENTIAL
    models[m].render(worldTransform,SEQUENTIAL,zBuffer,normalBuffer,localCoordBuffer,shaderBuffer);
  }

  int wh = width/2, hh = height/2;

  for(int i=0 ; i<width ; i++)
    for(int j=0 ; j<width ; j++){
      if( zBuffer[i][j] != minZBuffer ){
        Vector3D normal = normalBuffer[i][j];
        Vector3D pos = new Vector3D(i-wh,j-hh,zBuffer[i][j]);
        Shader shader = shaderBuffer[i][j];
        pixels[i+j*width] = shader.getColor(pos,normal,light);
      }
      else
        pixels[i+j*width] = color(0);
    }

  updatePixels();

}
//--------------------
void keyPressed(){
  if(!online)
    if(key=='s') saveFrame("scene-##.png");
}
//--------------------