class Perlin extends TextureFilter{
  float zoom;
  float[][] nodeMatrix;
  //----------------------
  public Perlin(){
    super("Perlin",0,0);
    zoom = 0.15f;
    // Skapar en rutnät av slumpade punkter att interpolera över
    nodeMatrix = new float[20][20];
    for(int i=0 ; i<20 ; i++ ){
      for(int j=0 ; j<20 ; j++ ){
        nodeMatrix[i][j] = random(0f,1f);
      }
    }
  }
  //----------------------
  Color output( float x, float y , float z){
    int xP,yP,xPp,yPp;
    float a,b,c,d,u,v;
    float shade;

    xP  = ((int)floor(x/zoom)) % 20;
    yP  = ((int)floor(y/zoom)) % 20;
    xPp = (xP+1) % 20;
    yPp = (yP+1) % 20;

    a = nodeMatrix[xP ][yP ];
    b = nodeMatrix[xPp][yP ];
    c = nodeMatrix[xP ][yPp];
    d = nodeMatrix[xPp][yPp];

    u = (x/zoom)-floor(x/zoom);
    u = 3*u*u - 2*u*u*u;
    v = (y/zoom)-floor(y/zoom);
    v = 3*v*v - 2*v*v*v;

    shade = (float)( (1-v)*( a*(1-u) + b*u ) + v*( c*(1-u) + d*u ) );
    return new Color( constrain( shade, 0, 1f) );
  }

}

//#################################################################
class White extends TextureFilter{
  White(){
    super("White",0,0);
  }
  //----------------------
  Color output( float x, float y , float z){
    return new Color(1);
  }
}
//#################################################################
class Grid extends TextureFilter{
  Grid(){
    super("Grid",0,2);
    setAttribute(0,"Scale",EXPONENTIAL, 0.05, 1.2);
    setAttribute(1,"Thickness",EXPONENTIAL, 0.005, 1.2);
  }
  //----------------------
  Color output( float x, float y , float z){
    float scale = getAttribute(0);
    float thickness = getAttribute(1);
    return new Color( (abs(x+0.5)%scale<thickness || abs(y+0.5)%scale<thickness) ? 0 : 1 );
  }
}
//#################################################################
class Noise extends TextureFilter{
  float offset = 47.11;
  Noise(){
    super("Noise",0,1);
    offset = random(47.11);
    setAttribute(0,"Scale",EXPONENTIAL, 16, 1.2);
  }
  //----------------------
  Color output( float x, float y , float z){
    float s = getAttribute(0);
    return new Color( noise( s*x+offset, s*y+offset, s*z+offset ) );
  }
}
//#################################################################
class GradientX extends TextureFilter{
  public GradientX(){
    super("x",0,0);
  }
  Color output( float x, float y , float z){
    return new Color(x);
  }
}
//#################################################################
class GradientY extends TextureFilter{
  public GradientY(){
    super("y",0,0,"");
  }
  Color output( float x, float y , float z){
    return new Color(y);
  }
}
//#################################################################
class Julia extends TextureFilter{
  Julia(){
    super("Julia",0,3,"Julia fractal.");
    setAttribute(0,"Scale",EXPONENTIAL, 3, 1.1);
    setAttribute(1,"Real",LINEAR, 0.38, 0.01);
    setAttribute(2,"Imaginary",LINEAR, 0.2, 0.01);
  }
  //----------------------
  Color output( float x, float y , float z){
    double xJ, yJ, xJ2, yJ2;
    float scale = getAttribute(0);
    int i=0, iterationMax = 128;
    xJ = (-0.5 + x) * scale;
    yJ = (-0.5 + y) * scale;

    do {
      xJ2 = xJ*xJ - yJ*yJ + getAttribute(1);
      yJ2 = 2*xJ*yJ + getAttribute(2);
      xJ = xJ2;
      yJ = yJ2;
      i++;
    } 
    while( (i<iterationMax) && (xJ*xJ + yJ*yJ < 4) );

    return new Color( sqrt(i/(float)iterationMax) );
  }
}
//#################################################################
class Paint extends TextureFilter{
  Paint(int r, int g, int b){
    super("Color",0,3);
    setAttribute(0,"Red",   LINEAR, random(255), 16);
    setAttribute(1,"Green", LINEAR, random(255), 16);
    setAttribute(2,"Blue",  LINEAR, random(255), 16);
  }
  //----------------------
  Color output( float x, float y , float z){
    return new Color( getAttribute(0)/255, getAttribute(1)/255, getAttribute(2)/255 );
  }
  //----------------------
  void drawNode(){
    super.drawNode();
    noStroke();
    fill(getAttribute(0),getAttribute(1),getAttribute(2));
    ellipse(x+radius/1.414,y+radius/1.414,5,5);
  }
}