class ImgBuffer{
  int saveImageScanline = 0;
  int scanlineBatch = 16;
  int saveImageSize = 800;
  int scanline = 0;
  PGraphics imgBuffer;
  //--------------------------------------------
  ImgBuffer(int w, int h){
    imgBuffer = createGraphics(w,h,P3D);
    imgBuffer.background(0);
  }
  //--------------------------------------------
  boolean isFinished(){
    return scanline >= imgBuffer.height;
  }
  //--------------------------------------------
  float getProgress(){
    return scanline / (float)imgBuffer.height;
  }
  //--------------------------------------------
  void partialRender(){
    float dx = 1f/(float)imgBuffer.width;
    float dy = 1f/(float)imgBuffer.height;
    imgBuffer.loadPixels();

    int maxScanline = min(scanlineBatch+saveImageScanline, imgBuffer.height);
    for( ; scanline<maxScanline ; scanline++ ){
      for(int x=0 ; x<imgBuffer.width ; x++ ){
        color a = root.output( x*dx     , scanline*dy      , 0f).getColor();
        color b = root.output( x*dx+dx/2, scanline*dy      , 0f).getColor();
        color c = root.output( x*dx     , scanline*dy+dy/2 , 0f).getColor();
        color d = root.output( x*dx+dx/2, scanline*dy+dy/2 , 0f).getColor();
        color col = lerpColor( lerpColor(a,b,0.5) , lerpColor(c,d,0.5) , 0.5);
        imgBuffer.pixels[x+scanline*imgBuffer.width] = col;
      }
    }
    imgBuffer.updatePixels();

    if( scanline >= imgBuffer.height )
      imgBuffer.save( savePath("output/texture-"+(int)random(100,999)+".png") );

    saveImageScanline += scanlineBatch;
  }
}