/*----------------------------------------\
 |   ____  _                               |
 |  / __/ | |_  _   _ _   _    _   ___     |
 |  [__[  |  / | [ | [ | | \  | \ |  /     |
 |  /___/ |__[ |__[|_[_| |__\ |__\|_|      |
 |                                         |
 |          T E X T U R I Z E R            |
 |                                         |
 \----------------------------------------*/

SkanaarGUI gui;
TextureFilter root;
TextureFilter selectedFilter;
TextureFilter connectionSelectedFilter;
int connectionSelectedSource = 0;
Vector filters;
int texWidth, texHeight, guiWidth, rootX, rootY;
boolean refresh = true;
boolean savingImage = false;
ImgBuffer imgBuffer;
int detail = 0;
PFont font;
final int LINEAR = 0, EXPONENTIAL = 1;
//--------------------------------------------
void setup(){
  size(800,500);
  frameRate(30);
  texWidth = 500;
  texHeight = height;
  guiWidth = width-texWidth;
  rootX = guiWidth/2;
  rootY = 200;
  smooth();
  font = loadFont("silkscreen.vlw");
  textFont(font);
  filters = new Vector();

  gui = new SkanaarGUI();
  gui.setDesign(font);
  String[] distorts= new String[]{"coords","warp","rotate","translate","scale","displace","swirl","bulge"};
  String[] filters = new String[]{"crease","monochrom","hue","invert","newsprint","colorprint","overlay","mix","add","multiply","tint","threshold"};
  String[] sources = new String[]{"color","grid","julia","noise","gradient x","gradient y"};
  distorts = sort(distorts);
  filters = sort(filters);
  sources = sort(sources);
  for(int i=0; i<sources.length; i++)
    gui.addButton(sources[i],sources[i],5,25+20*i);
  for(int i=0; i<distorts.length; i++)
    gui.addButton(distorts[i],distorts[i],70,25+20*i);
  for(int i=0; i<filters.length; i++)
    gui.addButton(filters[i],filters[i],guiWidth-70,25+20*i);
  if(!online) gui.addButton("save-img","save image",guiWidth-70,height-55);

  root = new Root();
  refresh();
}
//--------------------------------------------
void refresh(){
  refresh = true;
}
//--------------------------------------------
void setPixel(int x, int y, color c){
  pixels[width-texWidth + x + width*y] = c;
}
//--------------------------------------------
// 4 pixels per sample
void renderCoarse(){
  loadPixels();
  for(int y=0 ; y<texHeight ; y+=2 ){
    for(int x=0 ; x<texWidth ; x+=2 ){
      Color c = root.output( x/(float)texWidth, y/(float)texHeight , 0f);
      setPixel(x  ,y  , c.getColor() );
      setPixel(x+1,y  , c.getColor() );
      setPixel(x  ,y+1, c.getColor() );
      setPixel(x+1,y+1, c.getColor() );
    }
  }
  updatePixels();
}
//--------------------------------------------
// one sample per pixel
void renderNormal(){
  float dx = 1f / (float)texWidth;
  float dy = 1f / (float)texHeight;
  loadPixels();
  for(int y=0 ; y<texHeight ; y++ )
    for(int x=0 ; x<texWidth ; x++ )
      setPixel(x, y, root.output( x*dx, y*dy , 0f).getColor() );
  updatePixels();
}
//--------------------------------------------
// 4xSupersampled antialiasing
void renderSmooth(){
  float dx = 1f/(float)texWidth;
  float dy = 1f/(float)texHeight;
  loadPixels();
  for(int y=0 ; y<texHeight ; y++ ){
    for(int x=0 ; x<texWidth ; x++ ){
      color a = root.output( x*dx     , y*dy        , 0f).getColor();
      color b = root.output( x*dx+dx/2, y*dy      , 0f).getColor();
      color c = root.output( x*dx     , y*dy+dy/2   , 0f).getColor();
      color d = root.output( x*dx+dx/2, y*dy+dy/2 , 0f).getColor();
      color col = lerpColor( lerpColor(a,b,0.5) , lerpColor(c,d,0.5) , 0.5);
      setPixel(x, y, col);
    }
  }
  updatePixels();
}
//--------------------------------------------
void renderImage(){
  float dist;
  if(detail==0)
    renderCoarse();
  else if(detail==1)
    renderNormal();
  else if(detail==2)
    renderSmooth();
  refresh = false;
}
//--------------------------------------------
void draw(){
  stroke(0);
  strokeWeight(1);
  fill(192);
  rect(0,0,width-height-1,height-1);
  
  // removes killed filters
  for(int i=filters.size()-1 ; i>=0 ; i-- )
    if( getFilter(i).deleteMe )
      filters.remove(i);

  // make nodes moveable by mouse dragging
  if( selectedFilter!=null && selectedFilter!=root)
    if( mousePressed )
      selectedFilter.setIconPos(mouseX,mouseY);

  // nodes in trees order themselves nicely and every node repel each other 
  for(int i=0 ; i<filters.size() ; i++ ){
    getFilter(i).forces();
    for(int j=0 ; j<filters.size() ; j++ )
      getFilter(i).mutualRepulsion( getFilter(j) );
  }
  for(int i=0 ; i<filters.size() ; i++ )
    getFilter(i).updatePosition();
  root.setIconPos( rootX, rootY);

  // display nodes and connections
  for(int i=0 ; i<filters.size() ; i++ )
    getFilter(i).drawNode();
  for(int i=0 ; i<filters.size() ; i++ )
    getFilter(i).drawConnections();

  // interactive connection editing
  if( mousePressed ){
    strokeWeight(1);
    stroke(0,128+64*cos(0.1*frameCount));
    if( connectionSelectedFilter != null ){
      float x = connectionSelectedFilter.x + connectionSelectedFilter.sourceKnobs[connectionSelectedSource][0];
      float y = connectionSelectedFilter.y + connectionSelectedFilter.sourceKnobs[connectionSelectedSource][1];
      line(x,y,mouseX,mouseY);
    }
  }

  noStroke();
  fill(255,128);
  rect(0,height-30,guiWidth-1,30);
  rect(0,0,guiWidth-1,20);
  fill(0);
  textAlign(RIGHT);
  text("rendering quality: \"BNM\"",guiWidth-10,13);
  textAlign(LEFT);
  text("Modifier keys: \"QWASZX\"",10,13);
  if( selectedFilter != null ){
    text(selectedFilter.name +" : "+selectedFilter.description,10,height-17);
    text(selectedFilter.attributeDescription(),10,height-7);
  }

  if( refresh ){
    renderImage();
    if( detail==2 )
      detail = 1;
  }
  
  strokeWeight(1);
  gui.visualize();
  
  // the ImgBuffer class handles the progressive rendering and saving of high-res images
  if(savingImage){
    stroke(0);
    fill(0,128);
    rect(0,0,width,height);
    fill(255);
    noStroke();
    arc(width/2,height/2,100,100,-HALF_PI,TWO_PI*imgBuffer.getProgress()-HALF_PI);
    imgBuffer.partialRender();
    if(imgBuffer.isFinished())
      stopSavingImage();
  }
}
//--------------------------------------------
void startSavingImage(){
  imgBuffer = new ImgBuffer(800,800);
  savingImage = true;
}
//--------------------------------------------
void stopSavingImage(){
  refresh();
  savingImage = false;
}
//--------------------------------------------
void mousePressed(){
  for(int i=0 ; i<filters.size() ; i++ )
    getFilter(i).mouseDown(mouseX,mouseY);
}
//--------------------------------------------
void mouseReleased(){
  if( connectionSelectedFilter != null )
    for(int i=0 ; i<filters.size() ; i++ )
      if( getFilter(i).inside(mouseX,mouseY) ){
        connectionSelectedFilter.setSource(connectionSelectedSource,getFilter(i));
        connectionSelectedFilter = null;
        break;
      }
  String gizmo = gui.mouseInput(mouseX,mouseY);
  //println(gizmo);
  if(gizmo==null) gizmo = "";
  if( gizmo.equals("add") ) new Add();
  if( gizmo.equals("bulge") ) new Bulge();
  if( gizmo.equals("crease") ) new Crease();
  if( gizmo.equals("color") ) new Paint((int)random(255),(int)random(255),(int)random(255));
  if( gizmo.equals("colorprint") ) new ColorPrint();
  if( gizmo.equals("coords") ) new CoordinateMapping();
  if( gizmo.equals("displace") ) new Displace();
  if( gizmo.equals("gradient x") ) new GradientX();
  if( gizmo.equals("gradient y") ) new GradientY();
  if( gizmo.equals("grid") ) new Grid();
  if( gizmo.equals("hue") ) new Hue();
  if( gizmo.equals("invert") ) new Invert();
  if( gizmo.equals("julia") ) new Julia();
  if( gizmo.equals("mix") ) new Mix();
  if( gizmo.equals("monochrom") ) new Monochrome();
  if( gizmo.equals("multiply") ) new Multiply();
  if( gizmo.equals("newsprint") ) new NewsPrint();
  if( gizmo.equals("noise") ) new Noise();
  if( gizmo.equals("overlay") ) new Overlay();
  if( gizmo.equals("rotate") ) new Rotate();
  if( gizmo.equals("scale") ) new Scale();
  if( gizmo.equals("swirl") ) new Swirl();
  if( gizmo.equals("threshold") ) new Threshold();
  if( gizmo.equals("tint") ) new Tint();
  if( gizmo.equals("translate") ) new Translate();
  if( gizmo.equals("warp") ) new Warp();
  
  if( gizmo.equals("save-img") ) startSavingImage();
}
//--------------------------------------------
void keyPressed(){
  if(key>= '1' && key<='9')
    for(int i=0 ; i<filters.size() ; i++ )
      getFilter(i).keyPress(mouseX,mouseY,(int)key-'1');

  if( key=='b' ) detail = 0;
  if( key=='n' ) detail = 1;
  if( key=='m' ) detail = 2;
  if( key=='b' || key=='n' || key=='m' ) refresh();

  if(selectedFilter!=null){
    if(key=='q') selectedFilter.decreaseAttribute(0);
    if(key=='w') selectedFilter.increaseAttribute(0);
    if(key=='a') selectedFilter.decreaseAttribute(1);
    if(key=='s') selectedFilter.increaseAttribute(1);
    if(key=='z') selectedFilter.decreaseAttribute(2);
    if(key=='x') selectedFilter.increaseAttribute(2);

    if(key=='q'||key=='w'||key=='a'||key=='s'||key=='z'||key=='x') refresh();
    if(key==DELETE||key==BACKSPACE) selectedFilter.delete();
  }
}
//--------------------------------------------
TextureFilter getFilter(int i){
  return (TextureFilter) filters.get(i);
}
//--------------------------------------------
String format(double x){
  String[] s = split(x+"",'.');
  return s[0] +"."+ s[1].substring(0,min(s[1].length(),3) );
}