class WaterOld extends Terrain{
  float[][] changeMap;
  float[][] flow;
  float step = 0.9;
  float volume;
  Terrain terrain;
  //------------
  WaterOld( Terrain t, float pillarHeight ){
    super(t.w,t.h,t.res,t.zScale);
    this.terrain = t;
    wireframe = false;

    // initialize arrays
    flow = new float[res][res];
    changeMap = new float[res][res];
    for(int x=0;x<res;x++)
      for(int y=0;y<res;y++)
        vertexColor[x][y] = color(0,0,255);

    for(int x=0;x<terrain.res;x++)
      for(int y=0;y<terrain.res;y++)
        heightMap[x][y] = terrain.heightMap[x][y]-0.125;

    addMoreWater(pillarHeight);
  }
  //------------
  void randomWater(float pillarHeight){
    int spread = 2;
    int px = (int) random(spread,res-spread);
    int py = (int) random(spread,res-spread);
    for(int x=px-spread;x<px+spread;x++)
      for(int y=py-spread;y<py+spread;y++)
        heightMap[x][y] += pillarHeight;
  }
  //------------
  void addMoreWater(float pillarHeight){
    int spread = 3;
    for(int x=res/2-spread;x<res/2+spread;x++)
      for(int y=res/2-spread;y<res/2+spread;y++)
        heightMap[x][y] += pillarHeight;
  }
  //------------
  float getLevel(int i, int j){
    return max( heightMap[i][j], terrain.heightMap[i][j] );
  }
  //------------
  float getWaterHeight(int x, int y){
    return heightMap[x][y] - terrain.heightMap[x][y];
  }
  //------------
  float getDiff(int x, int y, int dx, int dy){
    return heightMap[x][y] - heightMap[dx][dy];
  }
  //------------
  void update(){
    for(int x=0;x<terrain.res;x++)
      for(int y=0;y<terrain.res;y++){
        changeMap[x][y] = 0;
        flow[x][y] = 0; // reset flow memory
      }

    volume = 0;

    // nearest neighbour map
    int[] nx = { 
      -1,1,0,0         };
    int[] ny = {
      0,0,-1,1            };
    float diff;
    for(int x=1; x<res-1; x++){
      for(int y=1; y<res-1; y++){
        if( getWaterHeight(x,y) > 0 ){ // water cell
          // calculate total volume
          volume += getWaterHeight(x,y);

          for(int i=0; i<4; i++){ // loop through the nearest neighbours
            if( 0 < (diff = getDiff(x,y,x+nx[i],y+ny[i])) ){
              changeMap[x+nx[i]][y+ny[i]] += step * diff/4;
              changeMap[x][y] -= step * diff/4;
              flow[x][y] += diff;
              flow[x+nx[i]][y+ny[i]] += diff;
            }
          }//endloop

        }// endif
      }
    }

    for(int x=0;x<terrain.res;x++)
      for(int y=0;y<terrain.res;y++){
        heightMap[x][y] += changeMap[x][y];
        //shallow streams should be more frothy
        flow[x][y] /= sqrt(1+getWaterHeight(x,y));
      }
    
    if(gouraud) makeNormals();
  }
  //------------
  float getHeight(int x, int y){
    return ( getWaterHeight(x,y)>0 ? heightMap[x][y] : heightMap[x][y]-4 );
  }
  //------------
  void buildVertexColors(){
    for(int x=1;x<res;x++){
      for(int y=1;y<res;y++){
        int index = (int)( (spectrum.length-1)*heightMap[x][y]/zScale );
        vertexColor[x][y] = color( 50*flow[x][y],50*flow[x][y],255,255 );
      }
    }
  }
}