/**
SPACE : l&auml;gg till vatten i mitten.<br>
R : Ta bort vatten fr&aring;n mitten.<br>
W : l&auml;gg till vatten slumpm&auml;ssigt.<br>
1-9 : modifiera v&aring;g-parametern.<br>
Q : sl&aring; av/p&aring; visning av separat terr&auml;ng (p&aring;verkar hastigheten!).<br>
A,S,D : modifiera renderingen av vattnet (gourad,textureBlending,wireframe).<br>
Z,X,C : modifiera renderingen av terr&auml;ngen (gourad,textureBlending,wireframe).<br>
T : slumpa fram ny terr&auml;ng.<br><br>

Det som slukar mest resurser &auml;r renderingen. Utan rendering har appletten skr&auml;mts upp i 30 fps f&ouml;r ett 333*333 grid, allts&aring; en miljon celler. :D<br>
Inte s&auml;rskilt spektakul&auml;rt, men det h&auml;nder n&aring;gonting iaf.<br>
Vitt vatten betyder starka str&ouml;mmar.
*/
Terrain terrain;
Water water;
float rotX=PI/3, rotZ=PI/6;
int mousePX=0, mousePY=0;
boolean drawTerrain = false;
//-------------------------
void setup(){
  size(500,500, P3D);
  terrain = new Terrain(64);
  water = new Water( terrain, 100 );
  frameRate(30);
}
//-------------------------
void draw(){
  background(255);
  //println( "total volume: "+(int)water.volume+"/"+(int)water.addedVolume );
  //println( "fps: "+frameRate );
  
  directionalLight(155,155,155, 0,0,-1);
  ambientLight(100,100,100);
  //lights();
  
  translate(width/2,width/2,0);
  if( mousePressed ){
    rotateX( rotX - (mouseY-mousePY)*PI/height );
    rotateZ( rotZ - (mouseX-mousePX)*TWO_PI/width );
  } else {
    rotateX( rotX );
    rotateZ( rotZ );
  }
  translate(0,0,-width*0.25);
  scale(1.0);

  water.update();
  water.visualize();
  if(drawTerrain) terrain.visualize();
}
//-------------------------
void mousePressed(){
  mousePX = mouseX;
  mousePY = mouseY;
}
//-------------------------
void mouseReleased(){
  rotX -= (mouseY-mousePY)*PI/height;
  rotZ -= (mouseX-mousePX)*TWO_PI/width;
}
//-------------------------
void keyPressed(){
  if(key>='1' && key<='9')  water.flowDecay = 0.5+(key-'1'+1.5)/20;
  
  if(key==' ')  water.addMoreWater( 30 );
  if(key=='r')  water.removeWater();
  if(key=='w')  water.randomWater( 30 );
  
  if(key=='q')  drawTerrain = !drawTerrain;
  
  if(key=='a')  water.gouraud = !water.gouraud;
  if(key=='s')  water.textureBlend = !water.textureBlend;
  if(key=='d')  water.wireframe = !water.wireframe;
  if(key=='z')  terrain.gouraud = !terrain.gouraud;
  if(key=='x')  terrain.textureBlend = !terrain.textureBlend;
  if(key=='c')  terrain.wireframe = !terrain.wireframe;
  if(key=='t')  water = new Water( terrain = new Terrain(64) , 0 );
}
//#########################